Re: How to track the error messages in CL program for called RPGLE programs -- RPG400-L

There are a variety of ways to accomplish what you desire, but following
your example:

DCL VAR(&GOOD) TYPE(*LGL)

CHGVAR VAR(&GOOD) VALUE('1')
CALL PGM(PGMA)
MONMSG MSGID(CPF9897) EXEC(CHGVAR VAR(&GOOD) VALUE('0'))
IF COND(&GOOD) THEN(DO)
CALL PGM(PGMB)
ENDDO

and

ctl-opt dftactgrp(*no);

dcl-pr SndEsc;
text char(132) const options(*varsize);
end-pr;

SndEsc ('Some unique message text');
*inlr = *on;
return;

dcl-proc SndEsc;
dcl-pi SndEsc;
text char(132) const options(*varsize);
end-pi;

dcl-pr SndPgmMsg extpgm('QMHSNDPM');
msgID char(7) const;
qualMsgF char(20) const;
msgDta char(4096) const options(*varsize);
lenMsgDta int(10) const;
msgTyp char(10) const;
cse char(10) const options(*varsize);
cseCtr int(10) const;
msgKey char(4);
errCde likeds(QUSEC);
lenCSE int(10) const options(*nopass);
qualCSE char(20) const options(*nopass);
dspWait int(10) const options(*nopass);
cseTyp char(10) const options(*nopass);
ccsid int(10) const options(*nopass);
end-pr;

/include qsysinc/qrpglesrc,qusec

dcl-ds errCde qualified;
hdr likeds(QUSEC);
msgData char(128);
end-ds;

dcl-s msgKey char(4);

// Set API error code ds to send exceptions
errCde.Hdr.qusBPrv = 0;

SndPgmMsg( 'CPF9897' : 'QCPFMSG *LIBL'
: text : %len(%trimr(text))
: '*ESCAPE' : '*PGMBDY' : 1 : msgKey :errCde);
end-proc SndEsc;

CPF9897 is simply an IBM provided message with a first level text of blanks
and you provide the text. In this case, 'Some unique message text'. I do
prefer this to adding a parameter when calling PGMA/PGMB as the joblog will
show what happens.

In practice I would probably create my own message file (CRTMSGF) and then
add unique messages (ADDMSGD) to send for each error situation (or perhaps
use some replacement data like the filename for a generic record not found
message ID). Likewise I would put SndEsc into a *SRVPGM for general
application use.

But this should give you one general approach.

On Thu, Dec 19, 2019 at 10:23 AM Bruce Vining <bruce.vining@xxxxxxxxx>
wrote:

I can safely say I would never have guessed techie21 was using DSPLY.
DSPLY sends *INFO message RNI5334, which is not an *ESCAPE -- *ESCAPE
being one of the message types (along with *NOTIFY and *STATUS) that can be
monitored (as has been mentioned in earlier responses by others). I'll
append an example shortly using *ESCAPE.

Bruce

On Thu, Dec 19, 2019 at 10:18 AM Vernon Hamberg <vhamberg@xxxxxxxxxxxxxxx>
wrote:

At a very quick glance, it looks like all you are doing is display an
error, and displaying an error does not SEND it in any fashion, so there
is nothing to monitor.

On 12/19/2019 8:59 AM, techie21 IT wrote:

Hi,

Below program (between stars ***) is unnecessarily trying to execute

pgm2

whereas why did it not understand that it already had received error

when

it had called program 1 and that too was not sufficient it tried to
execute program 2 as well and finally when i called this program i

ended up

error from 1st program 1 and then when i pressed enter it displayed

error

from second program pgm2 as well so it is not serving the purpose. just

to

explain in detail these customized errors from Program 1 and 2 are

getting

populated upon below such conditions:-
*******************************
DCL VAR(&GOOD) TYPE(*LGL)

CHGVAR VAR(&GOOD) VALUE('1')
CALL PGM(PGMA)
MONMSG MSGID(RXI0000 CPF0000 CPE0000 CPD0000 +
MCH0000) EXEC(DO)
CHGVAR VAR(&GOOD) VALUE('0')
ENDDO

IF COND(&GOOD) THEN(DO)
CALL PGM(PGMB)
ENDDO

***********************************
1) if fd less than 0 (fd used here to open some XML file located in some
directory )
dsply ('error message')

2) if %found(file name)
then assign some values to some fields

else

dsply ('some other error message')

3) if not %eof(file name)

do something

else

dsply ('some different error message')

4)Monitor;
vCommand = 'ADDLIBLE LIB(LIBHTTP) POSITION(*LAST)';
QCMDEXC(vCommand : %Len(%Trim(vCommand)) );
On-Error;
Dsply 'Unable to add library LIBHTTP ';
*InLr = *On;
return;

so these are just some examples as shown above similarly there are many
error messages which are invoked if certain conditions inside these

RPGLE

programs (program1 & Program2) fail.
so objective is that whenever this main driver CL program executes these
RPGLE programs it should be able
to understand what error each program invoked and whenever it traps any
such error either in program1 or in program 2
it must be able to tell clearly with error message description that this
error occured in this program and condition is
it should execute program2 only if program1 got executed successfully

and

in case later on program 2 gives some error
then it should clearly tell that error occured in program 2 and this is

the

error description and then after executing
this CL program let's say program 2 gave some error and when we called

this

CL program it showed particular error on program2 and
once we do F1 on that error message then we should be in condition to

know

exactly at which line at which program error occured.

Thanks much...

On Wed, Dec 18, 2019 at 4:15 PM <dlclark@xxxxxxxxxxxxxxxx> wrote:

"RPG400-L" <rpg400-l-bounces@xxxxxxxxxxxxxxxxxx> wrote on 12/18/2019
08:32:55 AM:

actually main thing is this logical indicator fails when i tried this
advised program and unnecessarily going to pgm2 evenif pgm1 had some
customized error messages like 'record not found'
'unable to open file'...etc.
means it has some if else conditions based on these conditions these

rpgle

programs throw these customized error messages.
how to use this &errorcode where to put it i mean any example for this
please?

I gave you this before and it works as long as these

customized

error messages you're talking about have message ids and they are

*ESCAPE

messages. In this case, add these message ids to the MONMSG below.

DCL VAR(&GOOD) TYPE(*LGL)

CHGVAR VAR(&GOOD) VALUE('1')
CALL PGM(PGMA)
MONMSG MSGID(RXI0000 CPF0000 CPE0000 CPD0000 +
MCH0000) EXEC(DO)
CHGVAR VAR(&GOOD) VALUE('0')
ENDDO

IF COND(&GOOD) THEN(DO)
CALL PGM(PGMB)
ENDDO

Sincerely,

Dave Clark
--
int.ext: 91078
direct: (937) 531-6378
home: (937) 751-3300

Winsupply Group Services
3110 Kettering Boulevard
Dayton, Ohio 45439 USA
(937) 294-5331

*********************************************************************************************

This email message and any attachments is for use only by the named
addressee(s) and may contain confidential, privileged and/or

proprietary

information. If you have received this message in error, please
immediately notify the sender and delete and destroy the message and

all

copies. All unauthorized direct or indirect use or disclosure of this
message is strictly prohibited. No right to confidentiality or

privilege

is waived or lost by any error in transmission.

*********************************************************************************************

--
This is the RPG programming on IBM i (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: https://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxxxxxxxx
Before posting, please take a moment to review the archives
at https://archive.midrange.com/rpg400-l.

Please contact support@xxxxxxxxxxxx for any subscription related
questions.

Help support midrange.com by shopping at amazon.com with our affiliate
link: https://amazon.midrange.com

--
This is the RPG programming on IBM i (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: https://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxxxxxxxx
Before posting, please take a moment to review the archives
at https://archive.midrange.com/rpg400-l.

Please contact support@xxxxxxxxxxxx for any subscription related
questions.

Help support midrange.com by shopping at amazon.com with our affiliate
link: https://amazon.midrange.com

--
Thanks and Regards,
Bruce
931-505-1915