Re: PSDS as parm

[Scott Klement <rpg400-l@xxxxxxxxxxxxxxxx>]

Hi Griz,

> Is it possible to pass the PSDS as a parm? If so can anyone tell me how
> I would map out the *PROC, *STATUS, *ROUTINE, *PARMS subfields?

I'm not exactly sure if this is what you're asking, but the following 
(rather silly) code seems to work okay for me:

     H DFTACTGRP(*NO)

     D PSDS           SDS                  qualified
     D   Proc            *PROC
     D   Status          *STATUS
     D   PrevStatus                   5S 0
     D   SrcStmt                      8A
     D   Routine         *ROUTINE
     D   Parms           *PARMS
     D   MsgID                        7A
     D                                4A
     D   MsgWork                     30A
     D   Lib                         10A
     D   ExcpDta                     80A
     D   ExcpID                       4A
     D   LastFile                    10A
     D                                6A
     D   JobDate                      8A
     D   Century                      2S 0
     D                                8A
     D   FileSts                     35A
     D   Job                         10A
     D   UserID                      10A
     D   JobNbr                       6S 0
     D   StrDate                      6S 0
     D   PgmRunDate                   6S 0
     D   PgmRunTime                   6S 0
     D   CrtDate                      6A
     D   CrtTime                      6A
     D   CompileLvl                   4A
     D   SrcFile                     10A
     D   SrcLib                      10A
     D   SrcMbr                      10A
     D   Program                     10A
     D   Module                      10A
     D   SrcStmtID                    5U 0
     D                                5U 0
     D   CurUser                     10A
     D                               62A

     D SomeProc        PR
     D   test                              likeds(PSDS)

      /free

          callp SomeProc(PSDS);
          *inlr = *on;

      /end-free

     P SomeProc        B
     D SomeProc        PI
     D   test                              likeds(PSDS)
      /free
           if test.CurUser = 'KLEMSCOT';
              dsply 'Hey, you''re me!';
           else;
              dsply 'You''re not me.';
           endif;
      /end-free
     P                 E