RE: XML-INTO is not populating entire ds array

["Montross, Shannon" <shannon.montross@xxxxxxxxxxxxxx>]

Hey thanks a lot, it works now. I was using the occurs because that's
how the example in the ILE RPG reference guide had it. 

-----Original Message-----
From: rpg400-l-bounces@xxxxxxxxxxxx
[mailto:rpg400-l-bounces@xxxxxxxxxxxx] On Behalf Of Scott Klement
Sent: Friday, October 05, 2007 1:21 PM
To: RPG programming on the AS400 / iSeries
Subject: Re: XML-INTO is not populating entire ds array

Hi Shannon,

I don't think XML-INTO is designed to load separate elements into
separate occurrences of a multiple-occurrence data structure.  As far as
it's concerned, there's only one data structure (the current occurrence)
and it'll load the XML into that occurrence -- thus you get only one
element.

Instead of using a multiple-occurrence data stucture (which is an
obsolete tool, IMHO) please use a data structure array.  This is what
I've seen used in all of the examples out there!

In your code, you have this:

D Product         DS                  Occurs(99)
D  Upc                          15A
D  Price                         6A
D  Price_Type                    1A

Change it so that it reads like this, instead:

D Product         DS                  dim(99) qualified
D  Upc                          15A
D  Price                         6A
D  Price_Type                    1A

This should solve your problem... now it will see that it's an array,
and load each product into a separate array element.  When you try to
read the contents of the subfields, you DO have to qualify them with the
name of the DS array.  In this example, you have Product as the name, so
if you want to access the UPC subfield, you'd code:

     x = 3;
     Whatever = Product(x).Upc;

And that'd set the "whatever" field to the contents of the UPC subfield
of the 3rd product that was loaded (in your example, 005150076080).  I'm
just telling you this so you understand the syntax of a qualified data
structure array (since I get the impression that you haven't used them,
you're using the older multiple-occurrence technique instead.)


Montross, Shannon wrote:
> I am new to the XML-INTO process and I am trying to read an xml 
> document into a data-structure array and I am only getting the first 
> item. Any help would be appreciated.
>
> Xml file.
> <SecSvyWceDataSet>
>   <Product>
>     <Upc>005150000286</Upc>
>     <Price>126</Price>
>     <Price_Type>R</Price_Type>
>   </Product>
>   <Product>
>     <Upc>005150076426</Upc>
>     <Price>126</Price>
>     <Price_Type>R</Price_Type>
>   </Product>
>   <Product>
>     <Upc>005150076080</Upc>
>     <Price>126</Price>
>     <Price_Type>R</Price_Type>
>   </Product>
>   <Product>
>     <Upc>005150076050</Upc>
>     <Price>126</Price>
>     <Price_Type>R</Price_Type>
>   </Product>
> </SecSvyWceDataSet>
>
> Program.
> D Product         DS                  Occurs(99)
> D  Upc                          15A
> D  Price                         6A
> D  Price_Type                    1A
>                                       
> D XML_Input       S            256A      Varying
>
> /FREE             
>   XML_Input = 'test20071005.xml';
>
>   XML-INTO Product %XML(XML_Input: 'case=any ' +
>                                    'path=SecSvyWceDataSet/Product ' +
>                                    'allowmissing=yes ' +
>                                    'doc=file ');
>      
>   *Inlr = *On;	                                         
> /END-FREE                                              
>
> When this program runs Products(1) has values for upc, price, and 
> price_type but array elements 2 through 15 are empty.
> Thanks,
>
> Shannon