Re: Odd problem passing a data structure to a procedure

David,

Check out this thread on the systemiNetwork:
http://www.systeminetwork.com/isnetforums/showthread.php?t=45802. Although
it deals with the specific issue of duplicate CONST parameters, it does
include some code to allow you to get any OpDesc information without using
CEEDOD...

Now I don't know whether the problem with CEEDOD returning a 0 for a DS is
with CEEDOD or is with the fact that the OD is passed incorrectly, but if
it's the former, you could try using the following code in a copybook to
bypass uisng CEEDOD:

D NPMPARMLISTADDR...
D                 PR              *   Extproc('_NPMPARMLISTADDR')
*
D NPMPARMLIST     DS                  Based(NPMPARMLIST@) Qualified
D   OpDescList@                   *
D                               16A
D   Argument@                     *   Dim(400)

D OpDescListDS    DS                  Based(OpDescListDS@) Qualified
D   NbrOfParms                  10I 0
D   Reserved1                    8A
D   ArgOpDesc                   10I 0
D   Reserved2                   16A
D   OpDesc@                       *   Dim(400) *
D OpDesc          DS                  qualified based(OpDesc@)
D   desc_type                    3I 0
D   data_type                    3I 0
D   desc_inf1                    3I 0
D   desc_inf2                    3I 0
D   data_len                    10I 0

and in your program use the following code instead of calling CEEDOD:

NPMPARMLIST@ = NPMPARMLISTADDR();
if NPMPARMLIST@ <> *null;
 OpDescListDS@ = NPMPARMLIST.OpDescList@;
 if OpDescListDS.NbrOfParms > 0;
   for ParmIndex = 1 to OpDescListDS.NbrOfParms;
     if NPMPARMLIST.Argument@( ParmIndex ) <> *null;
       OpDesc@ = OpDescListDS.OpDesc@( ParmIndex );
     endif;
   endfor;
 endif;
endif;

Try it out and let us know if it works.

Rory


On 12/1/06, David Gibbs <david@xxxxxxxxxxxx> wrote:

Lim Hock-Chai wrote:
> CEEDOD will return 0 if caller passes a data structure.  This problem
> has been fixed on V5R3.

Yep, found that.

> Lets have a vote:  :)
> Should IBM creates PTF to make the above fix available on previous OS?

Well, you have my vote ... I'd be happy to have it retrofitted to V5R2
(as that's the release that I'll be able to target pretty soon).

david
(who wonders if Barbara Morris can be bribed with a midrange.com button?)