AW: Dumb SQL question

Hi Jeff,

it's not possible to use hostvariables (leading :) in the Command-String.

You have the following options:
1. If the SQL statement never changes and only uses different dates, I'd
suggest to use static SQL:
C/EXEC SQL
C+ Declare MyCursor Cursor
C+     for Select * from dbmstf/ordtlhst
C+            where onrcu IN (SELECT   onrcu
C+                               from  dbmstf/orhdrhst
C+                               where shpdtiso between :BgnDate
C+                                                  and :EndDate)
C+            Order By NAMEK10, DATEKISO, TIMEKISO'
C/END-EXEC

C/Exec SQL  Open MyCursor
C/End-Exec

C/EXEC SQL  Fetch ...
C/End-Exec

C/EXEC SQL  Close MyCursor
C/End-Exec

2. If the SQL-Statement must be built dynamically, you have to use parameter
markers (?) instead of Host-Variables.
   The parameter markers get replaced in the open statement by specifying
USING :HostVariable

D FetchSQL        C    'SELECT * FROM dbmstf/ordtlhst +
D                      WHERE onrcu IN (SELECT onrcu FROM +
D                      dbmstf/orhdrhst WHERE +
D                      shpdtiso >= DATE(?) +
D                      AND +
D                      shpdtiso <= DATE(?)) +
D                      ORDER BY NAMEK10, DATEKISO, TIMEKISO'
 *------------------------------------------------------------------
 /Free
   MySQL = FetchSQL;
 /End-Free
C/exec sql
C+ prepare mainStatement
C+    from :MySQL
C/end-exec

C/exec sql
C+ declare MyCursor cursor
C+     for mainStatement
C/end-exec

C/EXEC SQL Open MyCursor Using :BgnDate, :EndDate
C/End-Exec

C/EXEC SQL Fetch ....
C/End-Exec

C/EXEC SQL Close MyCursor
C/End-Exec


Mit freundlichen Gruessen / Best regards

Birgitta

"Shoot for the moon, even if you miss, you'll land among the stars."
(Les Brown)