RE: Procedure Question.

Thank You, for taking the time to illustrate the problem and solution...

Tim 

-----Original Message-----
From: rpg400-l-bounces@xxxxxxxxxxxx [mailto:rpg400-l-bounces@xxxxxxxxxxxx]
On Behalf Of Scott Klement
Sent: Tuesday, October 18, 2005 4:52 PM
To: RPG programming on the AS400 / iSeries
Subject: Re: Procedure Question.


> If all the "file fields" are located in the sub-procedure, the fields 
> are never populated on my chain...

......

Starting in V5R2, you can read directly into a data structure. This bypasses
the input specs completely, and just loads the data from the record straight
into a data structure. Using that technique, you can read into fields that
are defined in the procedure. For example:

      FCUSTMAS   IF   E           K DISK
       // Note: CUSTMAS's record format name is "CUSTMASF"
       .
       .
      P Cust_GetCity    B                   export
      D Cust_GetCity    PI            15A
      D   CustNo                       4P 0 value

       // You must use the record format name with LIKEREC.
      D CustRec         DS                  likerec(CUSTMASF:*INPUT)

       /free

          if not %open(CUSTMAS);
             open CUSTMAS;
          endif;

          // Note: You must use the record format name on the CHAIN
          //  operation.

          chain CustNo CUSTMASF CustRec;
          if not %found;
             return *Blanks;
          else;
             return CustRec.City;
          endif;

       /end-free
      P                 E

Note that this isn't the same as an "external DS". (A data structure
declared with EXTNAME)

--
This is the RPG programming on the AS400 / iSeries (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxx To subscribe, unsubscribe, or
change list options,
visit: http://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives at
http://archive.midrange.com/rpg400-l.