RE: data structure array.

["Wilt, Charles" <CWilt@xxxxxxxxxxxx>]

Rob,

How about:

     D ServerEntry     ds
     D  Instance                     15a
     D  Server                       15a

     D WASList         ds                  qualified
     D                               90a   inz('default        server1   +
     D                                          WAS5Portal     WAS5Portal+
     D                                          IBMTEST        IBMTEST   ')
     D  entry                              dim(3) likeds(ServerEntry)
     D                                     overlay(WASList)

     D myServer        ds                  likeds(ServerEntry)
      /free

         myServer.Instance = WASList.entry(1).Instance;

         DSPLY myServer.Instance;

         *INLR = *ON;
         return;
      /end-free


or how about:

     D ServerEntry     ds
     D  Instance                     15a
     D  Server                       15a

     D ConstantData    s             90a   inz('default        server1   +
     D                                          WAS5Portal     WAS5Portal+
     D                                          IBMTEST        IBMTEST   ')

     D WASList         ds                  likeds(ServerEntry) dim(3)
     D                                     based(ptrWASList)

     D ptrWASList      s               *   inz(%addr(ConstantData))

     D myServer        ds                  likeds(ServerEntry)
      /free

         myServer.Instance = WASList(1).Instance;

         DSPLY myServer.Instance;

         *INLR = *ON;
         return;
      /end-free


HTH,

Charles Wilt
iSeries Systems Administrator / Developer
Mitsubishi Electric Automotive America
ph: 513-573-4343
fax: 513-398-1121
 

> -----Original Message-----
> From: rpg400-l-bounces@xxxxxxxxxxxx
> [mailto:rpg400-l-bounces@xxxxxxxxxxxx]On Behalf Of rob@xxxxxxxxx
> Sent: Tuesday, March 01, 2005 3:55 PM
> To: rpg400-l@xxxxxxxxxxxx
> Subject: data structure array.
> 
> 
> I can get this to work:
> 
>      D                 DS
>      D FmtData                       96    Inz('*MDY    *DMY  
>   *YMD    +
>      D                                          *JUL    *ISO  
>   *USA    +
>      D                                          *EUR    *JIS  
>   *CYMD   +
>      D                                          *CMDY   *CDMY 
>   *LONGJUL')
>      D FmtArray                       8    Overlay(FmtData) Dim(12) 
> 
> How can I get this to work:
>      D                 ds
>      D ConstantList                        inz('default       
>  server1  -
> RNF7030: The name or indicator CONSTAN... is not defined.
>      D                                          WAS5Portal    
>  WAS5Portal  
>   -
>      D                                          IBMTEST       
>  IBMTEST  ')
>      D WASList                             dim(3) 
> overlay(ConstantList)
> RNF7030: The name or indicator WASLIST is not defined.
>      D                                     likeDs(ServerList) 
> Qualified
> RNF3543: Keyword is not allowed within a data structure that is not 
> qualified.
> RNF3701: Keyword is not allowed for a subfield definition; keyword is 
> ignored.
>      D ServerList      ds
> RNF7031: The name or indicator SERVERLIST is not referenced.
>      D  Instance                     15a
> RNF7031: The name or indicator INSTANCE is not referenced.
>      D  Server                       15a
> 
> 
> Dropping the work Qualified didn't fix it.
> 
> Rob Berendt
> -- 
> Group Dekko Services, LLC
> Dept 01.073
> PO Box 2000
> Dock 108
> 6928N 400E
> Kendallville, IN 46755
> http://www.dekko.com
> 
> -- 
> This is the RPG programming on the AS400 / iSeries (RPG400-L) 
> mailing list
> To post a message email: RPG400-L@xxxxxxxxxxxx
> To subscribe, unsubscribe, or change list options,
> visit: http://lists.midrange.com/mailman/listinfo/rpg400-l
> or email: RPG400-L-request@xxxxxxxxxxxx
> Before posting, please take a moment to review the archives
> at http://archive.midrange.com/rpg400-l.
> 
>