Re: Getting source to old box

[rick.baird@xxxxxxxxxxxxxxx]

Bob,  if you decide on the DDM option, (and for the archives) try this
quickie utility I use for copying single or multiple members quickly across
iseries via DDM.

If authorities are right it allows you to copy in either direction.

Cmd Source:   CPYRMTSRC

             CMD        PROMPT('Copy Src From/To Remote System')

             PARM       KWD(LCLFILE) TYPE(*NAME) LEN(10) MIN(1) +
                          PROMPT('Local Source File Name')
             PARM       KWD(LCLLIB) TYPE(*NAME) LEN(10) MIN(1) +
                          PROMPT('Local Source Library Name')
             PARM       KWD(TOFRM) TYPE(*CHAR) LEN(5) RSTD(*YES) +
                          DFT(*FROM) VALUES(*TO *FROM) PROMPT('Copy +
                          From/To Remote System')
             PARM       KWD(RMTFILE) TYPE(*NAME) LEN(10) +
                          DFT(*LCLFILE) SPCVAL((*LCLFILE)) +
                          CHOICE('Name, *LCLFILE') PROMPT('Remote +
                          Source File Name')
             PARM       KWD(RMTLIB) TYPE(*NAME) LEN(10) DFT(*LCLLIB) +
                          SPCVAL((*LCLLIB)) CHOICE('Name, *LCLLIB') +
                          PROMPT('Remote Source Library Name')
             PARM       KWD(RMTLOCNAME) TYPE(*CNAME) LEN(10) MIN(1) +
                          PROMPT('Remote Location')
             PARM       KWD(MEMBER) TYPE(MEMB) PROMPT('Copy Member +
                          Name')

 MEMB:       QUAL       TYPE(*GENERIC) LEN(10) DFT(*ALL) +
                          SPCVAL((*ALL))

CL Source:  CPYRMTSRC

             PGM        PARM(&LCLFIL &LCLLIB &DIR &RMTFIL &RMTLIB +
                          &RMTLOC &RMTNID &MEMBER)

             DCL        VAR(&LCLFIL ) TYPE(*CHAR) LEN(10)
             DCL        VAR(&LCLLIB ) TYPE(*CHAR) LEN(10)
             DCL        VAR(&DIR    ) TYPE(*CHAR) LEN(5)
             DCL        VAR(&RMTFIL ) TYPE(*CHAR) LEN(10)
             DCL        VAR(&RMTLIB ) TYPE(*CHAR) LEN(10)
             DCL        VAR(&RMTLOC ) TYPE(*CHAR) LEN(10)
             DCL        VAR(&MEMBER ) TYPE(*CHAR) LEN(10)

             IF         COND(&RMTFIL *EQ '*LCLFILE') THEN(+
                        CHGVAR VAR(&RMTFIL) VALUE(&LCLFIL))

             IF         COND(&RMTLIB *EQ '*LCLLIB') THEN(+
                        CHGVAR VAR(&RMTLIB) VALUE(&LCLLIB))
             CRTDDMF    FILE(QTEMP/SOURCE) RMTFILE(&RMTLIB/&RMTFIL) +
                          RMTLOCNAME(&RMTLOC *IP)

             IF         COND(&DIR *EQ '*TO') THEN(DO)
               CPYSRCF    FROMFILE(&LCLLIB/&LCLFIL) +
                            TOFILE(QTEMP/SOURCE) FROMMBR(&MEMBER)
             ENDDO

             IF         COND(&DIR *EQ '*FROM') THEN(DO)
               CPYSRCF    FROMFILE(QTEMP/SOURCE) +
                            TOFILE(&LCLLIB/&LCLFIL) FROMMBR(&MEMBER)
             ENDDO

             DLTF       FILE(QTEMP/SOURCE)

 END:        ENDPGM

command:

Local Source File Name . . . . . LCLFILE    __________    Name
Local Source Library Name  . . . LCLLIB     __________    Name
Copy From/To Remote System . . . TOFRM      *FROM         *TO, *FROM
Remote Source File Name  . . . . RMTFILE    *LCLFILE__    Name, *LCLFILE
Remote Source Library Name . . . RMTLIB     *LCLLIB___    Name, *LCLLIB
Remote Location  . . . . . . . . RMTLOCNAME __________    Name
Copy Member Name . . . . . . . . MEMBER     *ALL______    Name, generic*,
*ALL