RE: monitoring for program going in message wait

Here is what I came up with. Not real pretty, but it works. It sends smtp
mail and the remote command stuff sends out a page. It runs continuously in
a separate batch queue:
             PGM
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)
             DCL        VAR(&CHECK) TYPE(*CHAR) LEN(7)
             DCL        VAR(&RTNTYPE) TYPE(*CHAR) LEN(2)
             DCL        VAR(&KEYVAR) TYPE(*CHAR) LEN(4)
             DCL        VAR(&MSGIN) TYPE(*CHAR) LEN(132)
 BEGIN:      CHGMSGQ    MSGQ(QSYSOPR) RESET(*YES)
             MONMSG     MSGID(CPF2451) EXEC(GOTO CMDLBL(M2451))
 MSG:        RCVMSG     MSGQ(QSYS/QSYSOPR) MSGTYPE(*INQ) RMV(*NO) +
                          KEYVAR(&KEYVAR) MSG(&MSGIN) MSGID(&MSGID) +
                          RTNTYPE(&RTNTYPE)
             MONMSG     MSGID(CPF2451) EXEC(GOTO CMDLBL(M2451))
             IF         COND(&MSGIN = '       ') THEN(GOTO +
                          CMDLBL(DONE))
             RCVMSG     MSGQ(QSYSOPR) MSGTYPE(*RPY) MSGKEY(&KEYVAR) +
                          RMV(*NO) MSG(&MSGIN) MSGID(&CHECK)
/*           IF COND(&MSGIN = '       ') THEN(GOTO CMDLBL(MSG)) */
             IF         COND(&RTNTYPE = '05') THEN(DO)
             SNDDST     TYPE(*LMSG) +
                          TOINTNET(('whoever@whatever.COM') +
                          ('whoever@whatever')) DSTD('!Message +
                          Queue QSYSOPR!') LONGMSG('Message Queue +
                          QSYSOPR has a message requiring a reply!')
             RUNRMTCMD  CMD('C:\APPS\PAGER\MSGW.CMD') +
                          RMTLOCNAME(CTCAPP02 *IP) +
                          RMTUSER(hooha) RMTPWD('hahoo')
             ENDDO
             GOTO       CMDLBL(MSG)
 M2451:      SNDDST     TYPE(*LMSG) +
                          TOINTNET(('whoever@whatever.COM') +
                          ('whoever@whatever.com')) +
                          DSTD('!Allocated Message Queue QSYSOPR!') +
                          LONGMSG('Message Queue QSYSOPR cannot be +
                          monitored - allocated to another job!')
             RUNRMTCMD  CMD('C:\APPS\PAGER\MSGW.CMD') +
                          RMTLOCNAME(CTCAPP02 *IP) +
                          RMTUSER(hooha) RMTPWD('hahoo')
 DONE:       CHGMSGQ    MSGQ(QSYSOPR) RESET(*YES)
             DLYJOB     DLY(600)
             GOTO       CMDLBL(BEGIN)
             ENDPGM

-----Original Message-----
From: Patrick Townsend [mailto:patownsend@patownsend.com]
Sent: Monday, November 19, 2001 10:52 PM
To: midrange-l@midrange.com
Subject: Re: monitoring for program going in message wait


Santosh,

One approach would be to create a job that runs every few minutes and
retrieves the status of the job. There is a system API (QUSRJOBA?) that can
retrieve the current status of a job. If the API returns a MSGW status for a
job you can send a message to the console.

Patrick
----- Original Message -----
From: <santoshp@lot.tatasteel.com>
To: <midrange-l@midrange.com>
Sent: Sunday, November 18, 2001 10:31 PM
Subject: monitoring for program going in message wait


> There are a number of batch programs being submitted in a subsystem
> MSGBATCH in our machine,
> at times , some of these jobs go to  MSGW.
> This position is unchanged until someone notices it and kills it .. Hence
> other jobs keep waiting . I cant avoid MSGW coming .
> My reqd is that whenever a program goes to MSGW in that subsystem, a
> message should be sent to sysopr on console monitor..
>
> How can i do that.??
> This  will really help me in eliminating one problem of mine from the root
> level.
> Thanks
> Santosh.
>
> Signature......................
>
> e- mail at :  santoshp@lot.tatasteel.com
> ITS, Tata Steel.
> Jamshedpur, India.
> Tel : 842134 (O) , 200279 (R).
>
> _______________________________________________
> This is the Midrange Systems Technical Discussion (MIDRANGE-L) mailing
list
> To post a message email: MIDRANGE-L@midrange.com
> To subscribe, unsubscribe, or change list options,
> visit: http://lists.midrange.com/cgi-bin/listinfo/midrange-l
> or email: MIDRANGE-L-request@midrange.com
> Before posting, please take a moment to review the archives
> at http://archive.midrange.com/midrange-l.
>
>

_______________________________________________
This is the Midrange Systems Technical Discussion (MIDRANGE-L) mailing list
To post a message email: MIDRANGE-L@midrange.com
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/cgi-bin/listinfo/midrange-l
or email: MIDRANGE-L-request@midrange.com
Before posting, please take a moment to review the archives
at http://archive.midrange.com/midrange-l.