Re: Invalid characters in the member.

The following bit of code will remove all hex highlight characters from a
source member and the call can be added to RDi as a 'User Action':

//****************************************************************
// CRTSQLRPGI ... DBGVIEW(*SOURCE) COMMIT(*NONE) <-Compile tip
// CALL SMWEST/RMVHILITES ('&F' '&L' '&N') <-User Action
//****************************************************************
ctl-opt dftactgrp(*no) actgrp('QILE');

dcl-s qualFile char(21) inz;
dcl-s ndx zoned(2);
dcl-s hexChar char(1);

dcl-s hilites char(32) inz(x'202122232425262728292A2B2C2D2E2F-
303132333435363738393A3B3C3D3E3F');

// Prototype for QCMDEXC program.
dcl-pr runCmd extpgm('QCMDEXC');
command char(1024);
length packed(15:5);
end-pr;
dcl-s cmdString char(1024);

dcl-s cmdLength packed(15:5);



// *ENTRY parameter list.

dcl-pi main extpgm('RMVHILITES');

pmFile char(10);

pmLibrary char(10);

pmMember char(10);

end-pi;



// Mainline.

qualFile = %trim(pmLibrary) + '/' + %trim(pmFile);

cmdString = 'ovrdbf srcFile ' + %trim(qualFile) +

' mbr(' + %trim(pmMember) + ')';

cmdLength = %len(%trim(cmdString));

runCmd(cmdString:cmdLength);



for ndx = 1 to 32;

hexChar = %subst(hilites:ndx:1);

exec SQL update srcFile set srcdta = replace(srcdta, :hexChar, '
');
endfor;

// Normal Termination.
*inlr = *on;
return;


Stephen West
Sr Software Engineer
Stillwater Insurance Group
W: (402)599-8325 | C(402)659-0452
Stephen.West@xxxxxxxxxxxxxxxxxxxxxxx