Re: Stopping processing with using a bunch of if statements

I agree issuing message is nice but can be complex and, sometimes, not
really flexible.

A simpler model can be:

Dcl-s i int(10);

Dcl-Ds bErr qualified inz;
N int(10) inz(0);
Short varchar(100) dim(999) inz('');
Long varchar(2000) dim(999) inz('');
Info ind dim(999) inz(*off);
Warning ind dim(999) inz(*off);
Escape ind dim(999) inz(*off);
Dcl-Ds Gen;
Info ind inz(*off);
Warning ind inz(*off);
Escape ind inz(*off);
End-Ds;
End-Ds;

Reset bErr;

exsr MainCode;
for i = 1 to bErr.n;
snd-msg 'ErrNbr ' + %char(i)
+ ' - ' + bErr.Short(i)
+ ' - ' + bErr.Long(i)
%target(*caller:1);
EndFor;

*inlr = *on;
return;

Begsr MainCode;

Dou *on;

Proc1(' ');
if bErr.Gen.Escape;
leave;
EndIf;

Proc1('X');
if bErr.Gen.Escape;
leave;
EndIf;

Proc1('A');
if bErr.Gen.Escape;
leave;
EndIf;

EndDo;

EndSr;

Dcl-Proc Proc1;
Dcl-pi *n ind;
Parm1 char(1) const;
End-Pi;

Select Parm1;
when-is *blanks;
RegErr('No value passed':'Pass a value to execute');
Return *on;
when-is 'X';
RegErr('Passed value X':'Value is X':'I');
Return *off;
other;
RegErr('Wrong value':'Pass X or empty':'E');
Return *on;
EndSl;

End-Proc;


Dcl-Proc RegErr;

Dcl-pi *n opdesc;
Short like(bErr.Short) const;
Long like(bErr.Long) const;
Type char(1) const options(*nopass);
End-pi;

Dcl-s lType like(Type) inz('W');

if bErr.n = %elem(bErr.Short);
return ;
endif;

bErr.n += 1;
bErr.Short(bErr.n) = Short;
bErr.Long(bErr.n) = Long;

if %passed(Type) and Type <> *blanks;
lType = %upper(Type);
endif;

Select lType;
when-is 'W';
bErr.Warning = *on;
bErr.Gen.Warning = *on;
when-is 'E';
bErr.Escape = *on;
bErr.Gen.Escape = *on;
other;
bErr.Info = *on;
bErr.Gen.Info = *on;
EndSl;

Return;

HTH
--
Marco Facchinetti

Mr S.r.l.

Tel. 035 962885
Cel. 393 9620498

Skype: facchinettimarco


Il giorno mer 14 feb 2024 alle ore 23:10 <smith5646midrange@xxxxxxxxx> ha
scritto:

I have an RPGLE program that calls a number of procedures. If it is in a
procedure and it detects an error, I want it to stop processing and exit
back to the main procedure where the initial screen is displayed to inform
the user of the error. I do not want the program to abend. Is there a way
do to this without placing an if statement after each procedure? That
could
get really ugly and it would probably be easy to miss one because not all
procedures can encounter an error.



Here is an example.



Errorfound is an indicator type variable.



Begin Main;

Display screen for input;

Procedure1();

Display screen showing results of processing;

End Main;



Begin Procedure1

Procedure2();

If Errorfound;

return;

endif;

Procedure3();

If Errorfound;

return;

endif;

Procedure4();

If Errorfound;

return;

endif;

.more code

End Procedure1;



Begin Procedure2;

Whatever code is needed

If an error is encountered.

Errorfound = *on;

Return;

Endif;

End Procedure2;



Begin Procedure3;

Whatever code is needed

If an error is encountered.

Errorfound = *on;

Return;

Endif;

End Procedure3;



Begin Procedure4;

Whatever code is needed

If an error is encountered.

Errorfound = *on;

Return;

Endif;

End Procedure4;



--
This is the RPG programming on IBM i (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: https://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxxxxxxxx
Before posting, please take a moment to review the archives
at https://archive.midrange.com/rpg400-l.

Please contact support@xxxxxxxxxxxxxxxxxxxx for any subscription related
questions.