Re: tiny free format program with parametes and without cycle

Here's a quick example...  the MAIN keyword declares a given procedure as the main procedure (rather than a subprocedure) so when this program is CALLed, it will run the getdow procedure, and no cycle will be used.

**free
ctl-opt main(getdow);

dcl-proc getdow;

  dcl-pi *n;
    in_date char(8) const;    // input date YYYYMMDD
    out_dow packed(1: 0);     // day of week, 0=Sunday 6=Saturday
  end-pi;

  dcl-c SUNDAY const(d'1899-12-31');
  dcl-s tempDate date;
  dcl-s totalDays int(20);

  tempDate = %date(in_date:*ISO0);
  totalDays = %diff(tempDate: SUNDAY: *DAYS);
  out_dow = %rem(totalDays:7);

  return;

end-proc;


On 9/3/2019 6:10 AM, Gad Miron wrote:

Hello Guys

I need to create a callable PGM that accept a date parameter (YYYYMMDD)
and returns a DayOfWeek parameter

I've created a free format PGM alright (with Pr and PI) but I'm
stymied with making
a no-Cycle version.

I've read that using a clt- option *NOMAIN is for a Module only.

Is it possible to write such a (no cycle) program and compile it with
CRTBNDRPG in one pass
Or do I have to resort to CRTRPGMOD + CRTPGM ?

TIA
Gad