Re: qualified DS within a qualified DS

"RPG400-L" <rpg400-l-bounces@xxxxxxxxxxxxxxxxxx> wrote on 01/09/2019
10:12:20 AM:

SQLRPGLE program..

2307 dcl-ds return_array Qualified;
2308 count_articles int(5) ;
2309 dcl-ds articles dim(999) Qualified;
====> aaaaaaaaa
NF0202 20 a 003300 KEYWORD NOT ALLOWED FOR A NESTED DATA STRUCTURE
SUBFIELD.
2310 id int(10);
2311 itemNumber char(15);
2312 assetId char(15);
2313 userId char(64);
2314 vinNumber char(18);
2315 articleId int(10);
2316 systemId int(5);
2317 typeId int(5);
2318 articleSecondaryId char(15);
2319 description char(30);
2320 count_locations int(5) ;
2321 dcl-ds locations Dim(20) Qualified;
====> aaaaaaaaa
NF0202 20 a 004500 KEYWORD NOT ALLOWED FOR A NESTED DATA STRUCTURE
SUBFIELD.
2322 locationId int(10);
2323 locationLabel char(64);

Yep, I would have coded that as follows. But, the last time I
checked, the SQL precompiler can not handle more than one level of
qualification.


dcl-ds location qualified template;
locationId int(10);
locationLabel char(64);
end-ds;

dcl-ds article qualified template;
id int(10);
itemNumber char(15);
assetId char(15);
userId char(64);
vinNumber char(18);
articleId int(10);
systemId int(5);
typeId int(5);
articleSecondaryId char(15);
description char(30);
count_locations int(5) ;
locations likeds(location) dim(20);
end-ds;

dcl-ds return_array qualified;
count_articles int(5);
articles likeds(article) dim(999);
end-ds;


Sincerely,

Dave Clark