Re: Printer file not supported in EXTNAME?

[Scott Klement <rpg400-l@xxxxxxxxxxxxxxxx>]

Interesting... I would've done it the following way:

     FJEFFPRT   O    E             PRINTER

     D jeffout         ds                  likerec(jeffr:*output)

      /free
          jeffout.field1='bubba';
          jeffout.field2='billy';
          write jeffr jeffout;
          *inlr = *on;
      /end-free

This way will run slightly faster (though, you probably wouldn't notice 
the difference) and it helps with the length limitation...  with PREFIX 
the total length of the field 'JEFFOUT.FIELD1' must be 14 chars or less 
(yours is exactly 14) because it has to fit in an output spec (the 
O-spec is generated by the compiler, but it's still an O-spec and still 
conforms to the rules of O-specs.)

In my example, above, no O-spec is used, it just copies the DS as one 
big block of memory to the print file's record buffer, so there's no 
limit on the fieldname size...

I guess I'm surprised that nobody is recommending this way vs. prefix...


rob@xxxxxxxxx wrote:
> Thank you!  This works like a charm!
>
>      FJEFFPRT   O    E             PRINTER PREFIX('JEFFOUT.')
>      D   jeffout     E DS                  EXTNAME(JEFFPRT:jeffr:*output)
>      D                                     QUALIFIED
>       /FREE
>        jeffout.field1='bubba';
>        jeffout.field2='billy';
>        write jeffr;
>        *inlr=*on;
>        return;
>       /end-free
>
> Rob Berendt