Re: RPG Socket fails after a number of communications -- RPG400-L

The error is CPE3452 - "Too many open files for this process." After Icancel the program, even my PING's sometimes fail to servers that I canping under other jobs.

Sounds like the sockets aren't closing. (PING uses sockets as well, so ifyour job is out of available sockets, PING won't work either.)

I'm using the close(SktID) API with no -1 return conditions. Doesanyone know if close(SktID) doesn't actually work for sockets?

If the close() API doesn't work with sockets (as you suggest) then thefollowing code should produce an error, right?


     H dftactgrp(*NO)
      /copy socket_h
     d SktId           s             10I 0
     d x               s             10I 0

      /free

       for x = 1 to 5000;

          SktId = socket(AF_INET: SOCK_STREAM: IPPROTO_IP);
          if (SktId < 0);
              dsply ('failed at ' + %char(x));
              leave;
          endif;
          callp close(SktId);

       endfor;

       *inlr = *on;

      /end-free

After all, your job can only handle 255 open descriptors, and several areused by the operating system. You'd be lucky to get 200 open -- yet thatcode tries to open 5000.

However, I don't get any errors when I run it. Therefore, the close() APImust be doing it's job.

Of course, it could be different after a connection is made, right? Solet's try connecting 5000 times in a loop....


     H dftactgrp(*NO)
      /copy socket_h
     d SktId           s             10I 0
     d x               s             10I 0
     D connto          ds                  likeds(sockaddr_in)

      /free

       for x = 1 to 5000;

          SktId = socket(AF_INET: SOCK_STREAM: IPPROTO_IP);
          if (SktId < 0);
              dsply ('failed at ' + %char(x));
              leave;
          endif;

          connto = *allx'00';
          connto.sin_family = AF_INET;
          connto.sin_port   = 23;
          connto.sin_addr   = INADDR_LOOPBACK;

          if (connect(SktId: %addr(Connto): %size(Connto)) < 0);
              dsply ('conn failed at ' + %char(x));
              callp close(SktId);
              leave;
          endif;

          callp close(SktId);

       endfor;

       *inlr = *on;

      /end-free

This code also runs without any errors on my system. Granted, it takes alot longer than the previous example (because it builds so many connectionattempts!) but it doesn't have any problem with running out ofdescriptors.

I guess the difference could be that I'm connecting to a loopback, andyou're connecting to a different computer. Okay, I'll try changing theconnection request to look like this:


      connto = *allx'00';
      connto.sin_family = AF_INET;
      connto.sin_port   = 23;
      connto.sin_addr   = inet_addr('192.168.5.1');

(That's a separate computer on my LAN). When I run this, I also get noerrors. Clearly, the close() API is serving it's purpose in closing thesocket.

Is it possible that there's a bug in your code that's causing it to bypassthe close() API?


Or, perhaps your prototype for the close() API is incorrect?

If you use netstat *cnn, does it show that the sockets are closing?