Re: How to tell *FILE object is PF-DTA or PF-SRC

Ben,

Here is a code fragment that does it (obviously from the time we did not 
have %bitxxx BIFs):

     C*  Ophalen gegevens data base file
     C                   CALLP     QDBRTVFD     (DbfInf
     C                                     :%len(DbfInf)
     C                                          :DbfRtn
     C                                          :'FILD0100'
     C                                          :DbfObj
     C                                          :*BLANK
     C                                          :'1'
     C                                          :'*LCL'
     C                                          :'*INT'
     C                                          :ErrDts)
     C
     C*  Verwerken (indien geen fouten)
     C                   IF        BytAva      = 0
     C
     C*  Bestandstype 'D'ata of 'S'ource
     C                   EVAL      DTSRC=        'D'
     C                   TESTB     '4'           DbfFl1                   
50
     C   50              EVAL      DTSRC=        'S'
     C
     C                   ENDIF

Definitions of parameters:
     D*  Parameters voor ophalen gegevens data base file
     D DbfObj          DS            20
     D   DbfNme                      10A
     D   DbfLib                      10A

     D DbfRtn          DS            20
     D   DbrNme                      10A
     D   DbrLib                      10A

     D DbfInf          DS          2000    INZ
     D   DbfFl1                9      9A

This is the prototype of QDBRTVFD (from an include member):
     D*  Retrieve data base file information
     D QDBRTVFD        PR                  EXTPGM     ('QDBRTVFD')
     D   DbfInf                       1A   OPTIONS    (*VARSIZE)
     D   DbfInfLen                   10U 0 CONST
     D   DbfRtn                      20A
     D   FmtNme                       8A   CONST
     D   DbfInp                      20A   CONST
     D   RfmNme                      10A   CONST
     D   OvrPrc                       1A   CONST
     D   SysNme                      10A   CONST
     D   FmtTyp                      10A   CONST
     D   ErrDts                       1A   OPTIONS    (*VARSIZE:*NOPASS)

Definition of error data structure (same include member);
     D/IF NOT DEFINED(ERRDTS)
     D/DEFINE ERRDTS
     D*  Error parameter data structure
     D ErrDts          DS
     D   BytPrv                      10I 0 INZ        (%size(ErrDts))
     D   BytAva                      10I 0 INZ
     D   ErrIdt                       7A   INZ
     D   ErrDta                     100A   INZ
     D/ENDIF

Joep Beckeringh