Eliminating MOVE

["Brian Parkins" <PARKIB@xxxxxxxxxx>]

Try this:

     D Date8           S              8  0 INZ(20031231)
     D IsoDate         S               D

     D DateDS          DS
     D  NumDate                       8S 0
     D  CharDate                      8A   Overlay(NumDate)

       // Original code
     C                   Eval      IsoDate = %date(Date8:*iso)
     C     isodate       adddur    1:*DAYS       IsoDate
     C                   move      IsoDate       Date8

       // Semi-free format at V5R1
       // NOTE: All BIFs can be used in semi-free or free format coding
style
     C                   Eval      IsoDate = %date(Date8:*iso)
     C                   Eval      IsoDate = IsoDate + %Days(1)
     C                   Eval      CharDate = %Char(IsoDate:*Iso0)
     C                   Eval      Date8 = NumDate

       // Semi-free format at V5R2
       // NOTE: %INT, %DEC, etc. enhanced to convert from character
     C                   Eval      IsoDate = %date(Date8:*iso)
     C                   Eval      IsoDate = IsoDate + %Days(1)
     C                   Eval      Date8 = %Int(%Char(IsoDate:*Iso0))


         // Free format style would allow the code (in both examples) to be
         //  shifted left and the EVAL to be dropped, e.g.
      /Free
         IsoDate = %date(Date8:*iso);
         IsoDate = IsoDate + %Days(1);
         Date8 = %Int(%Char(IsoDate:*Iso0));
         *InLR = *On;
      /End-Free

Brian Parkins