Re: PDM Default Options, F18. Where are they stored, how toretrieve them in an RPG program.

Hello John,

Here's a snippet - based on a similar example written by Gene Gaunt - 
demonstrating how to get at the PDM defaults.

I've just (almost) outlaid the information from first 4 index entries - using 
the dmpsysobj option described in other mails you could surely identify the 
rest of the fields...

Unless patched to system state the program only runs at security level 30 or 
below.

     H DftActGrp( *No )
     **
     D pPrf            s               *   ProcPtr
     D Ctx             s             20a   Inz
     D DtaElm          c                   4
     **
     D Arg             Ds            96
     D Key                           33a
     D  Key1                          1a   Inz( x'02' )
     D                                     Overlay( Key:  1 )
     D  Key2                         10a   Inz( 'QUOPDM    ' )
     D                                     Overlay( Key:  2 )
     D  Key3                         10a   Inz( 'SERVICES  ' )
     D                                     Overlay( Key: 12 )
     D  Key4                         10a   Inz( 'PROFINFO  ' )
     D                                     Overlay( Key: 22 )
     D  Key5                          5i 0 Inz( 0 )
     D                                     Overlay( Key: 32 )
     D                               15a
     D Data                          48a
     **
     D Opt             Ds            14
     D RuleOption                     5i 0 Inz( 1 )
     D ArgLength                      5i 0 Inz( %Len( Key ))
     D ArgOffset                      5i 0 Inz( 0 )
     D OccurCount                     5i 0 Inz( 1 )
     D ReturnCount                    5i 0 Inz( 0 )
     D EntryLength                    5i 0 Inz( 0 )
     D EntryOffset                    5i 0 Inz( 0 )
     **
     D PdmInfo         Ds
     D                               16a
     D  PiSrcLib                     10a
     D  PiRplObj                      1a
     D  PiCmpBch                      1a
     D  PiJobD                       10a
     D  PiJobLib                     10a
     D  PiChgTyp                      1a
     D  PiOptF                       10a
     D  PiOptLib                     10a
     D  PiOptMbr                     10a
     D  PiFulScnMod                   1a
     D  PiRunBch                      1a
     D  PiLibPdmLib                  10a
     D  PiObjPdmLib                  10a
     D  PiObjPdm                     10a
     D  PiObjTyp                     10a
     D  PiObjAtr                     10a
     D  PiMbrPdmLib                  10a
     D  PiMbrPdmF                    10a
     D  PiMbrPdmMbr                  10a
     D  PiMbrPdmTyp                  10a
     D  PiFlgx                        1a
     D  PiLibx                       10a
     D  PiObjx                       10a
     **
     D  PiData                       48a   Dim( DtaElm )  Overlay( PdmInfo )
     **
     D Rslvsp2         Pr                  ExtProc( '_RSLVSP2' )
     D                                 *   ProcPtr
     D                               34a   Const
     **
     D Get             Pr                  ExtProc( '_FNDINXEN' )
     D                                 *   Value
     D                                 *   ProcPtr
     D                                 *   Value
     D                                 *   Value
     **
     C     *Entry        Plist
     C                   Parm                    User             10
     **
     C                   CallP     Rslvsp2( pPrf
     C                                    : X'0EC4' + User + Ctx + x'0000'
     C                                    )
     **
     C                   For       Key5 = 0  to DtaElm - 1
     **
     C                   CallP     Get( %Addr( Arg )
     C                                : pPrf
     C                                : %Addr( Opt )
     C                                : %Addr( Arg )
     C                                )
     **
     C                   Eval      PiData( Key5 + 1 ) = Data
     **
     C                   EndFor
     **
     C                   Eval      *InLr = *On
     **

Best regards,
Carsten Flensburg

----- Original Message ----- 
From: "Rusling, John B. (Alliance)" <jbrusling@alliancedev.com>
To: <rpg400-l@midrange.com>
Sent: Wednesday, January 08, 2003 7:15 PM
Subject: PDM Default Options, F18. Where are they stored, how to retrieve them 
in an RPG program.


> Group,
> 
> I'd like to retrieve the PDM default options (gotten to by pressing F18 from
> the wrkmbrpdm screen).  It sets up things like compile in Batch or
> Interactive etc....
> 
> Anyone know where they are stored please?  File? Data Area?