Re:

[Contractor1@xxxxxxxxxxxxxxxxx]

Here's my Get Sunday's Date routine for what it is worth. It uses a date
file. Someone else probably has a better one that is solely calculations on
a set date.

Just to let you know. I use a pound(#) sign to distinguish program defined
vars.

Any questions, give me a call. Also, if anyone else has any comments about
my coding I welcome criticism.

 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
 * Get Sunday's Date (for the week of the date passed)
 *
 * by Patrick Conner
 *
 * To return Sunday's Date this procedure needs:
 * - A date field
 *
 * Indicator Usage Summary:
 *   99    : General
 *
 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
 * Modifications:
 *
 * When       Who  What
 * ---------- ---- -------------------------------------------------------
 * 06/23/2000 PWC  New Program. Copied from NxtBase.
 *
 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

HNoMain

 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
 * Files
 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

 * Date File
FDateFilX  IF   E           K Disk

 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
 * Procedure definition
 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

DGetSunDt         PR              D
D #StrDate                        D   Const
D #Error                        64A

PGetSunDt         B                   Export

DGetSunDt         PI              D
D #StrDate                        D   Const
D #Error                        64A

 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
 * Stand alone var definitions
 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
D#SunDate         S               D
D#Date8           S              8S 0

 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
 * Procedure calcs
 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

 ** Clear error
C                   Eval      #Error = *blank

 ** Get Monday's Date from the Date File
C                   Move      #StrDate      #Date8
C     #Date8        Chain     DatF
C                   If        not %found(DateFilX)
C                   Eval      #Error = 'Date passed is not found in the -
C                             Date File (DateFilX).'
C                   Eval      #SunDate = *LoVal
C                   Else
 ** Deduct one for Sunday's Date
C                   Test(DE)                WkOfDt
C                   If        %error
C                   Eval      #Error = 'The Week Of Date (Monday''s Date)-
C                             in the Date File (DateFilX) is invalid.'
C                   Eval      #SunDate = *LoVal
C                   Else
C                   Move      WkOfDt        #SunDate
C                   SubDur    1:*d          #SunDate
C                   EndIf
C                   EndIf

 ** Return Sunday's Date
C                   Return    #SunDate

 *:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
PGetSunDt         E


Patrick Conner
www.ConnecTown.com
(828) 244-0822


+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---