System Name

The QWCRSSTS API will also retrieve the system name - slightly easier to
use than QWCRNETA.

 ** Parameter section for QWCRSSTS (Retrieve System Info) API
D  SysIRcv        DS            80
D    SysName                     8A   Overlay(SysIRcv:17)
D  SysILen        S             10I 0 Inz(%Len(SysIRcv))
D  SysIFormat     S              8A   Inz('SSTS0100')
D  SysIReset      S             10A   Inz('*YES')

 ** General error code structure for APIs
D  ErrorCode      DS            16
D    ByteIn                     10I 0 Inz(%Len(ErrorCode))
D    ByteRet                    10I 0
D Qwcrssts        PR                  ExtPgm('QWCRSSTS')
D                               80A
D                               10I 0
D                                8A
D                               10A
D                               16A

 *****************************************************************
 ** Obtain System Name                                           *
 *****************************************************************

C                   CallP(E)  Qwcrssts(SysIRcv:SysILen:SysIFormat:
C                                 SysIReset:ErrorCode)

C                   If        (Not %Error) And (ByteRet = 0)
C     SysName       Dsply     '*REQUESTER'
C                   Endif

C                   Eval      *INLR = *ON
C                   Return

Brian Parkins


+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---