Re: Help with processing an array

On 6/22/2016 5:14 PM, dlclark@xxxxxxxxxxxxxxxx wrote:

d dsHeader_Columns...
d ds qualified
d Hdr_Col_A 35a inz('Row_Number')
d Hdr_Col_B 35a Inz('Zero Part Number')
d Hdr_Col_C 35a inz('Status')
d Hdr_Col_D 35a inz('AX Part No')
d Hdr_Col_E 35a inz('Vendor - Holly ADD')
d Hdr_Col_F 35a inz('lbs/ft conversion -
Holly')
d Hdr_Col_G 35a inz('lbs/pc (if pc is 10.5ft)')
d Hdr_Col_H 35a inz('inches per piece')
d item 35a dim(58)
overlay(dsHeader_Columns:1)

Then reference it as follows:

if StrVal <> %trim(dsHeader_Columns.item(Header_Column));

Darryl, if you don't ever need to reference the Hdr_Col_x subfields by name, an alternative is to just use an ordinary array with compile-time data to set the initialization values.

d dsHeader_Columns...
d s 35a dim(58) ctdata

if StrVal <> %trim(dsHeader_Columns(Header_Column));

**ctdata dsHeader_Columns
Row_Number
Zero Part Number
Status
AX Part No
Vendor - Holly ADD
lbs/ft conversion - Holly
lbs/pc (if pc is 10.5ft)
inches per piece

If you want the visual cue of A B C etc, you could code two "alternate" arrays to receive the compile-time data. The Labels array would get the first two characters of the ctdata and the Columns array would get the rest.

d dsHeader_Labels...
d s 2a dim(58) ctdata
d dsHeader_Columns...
d s 35a dim(58)
d alt(dsHeader_Labels)

if StrVal <> %trim(dsHeader_Columns(Header_Column));

**ctdata dsHeader_Labels
A Row_Number
B Zero Part Number
C Status
D AX Part No
E Vendor - Holly ADD
F lbs/ft conversion - Holly
G lbs/pc (if pc is 10.5ft)
H inches per piece

Barbara