Re: Problem with open in MAILR

Create them in /tmp. Copy them to the final directory doing something
like
CPY OBJ(&QP1ARCY) TODIR('/qntc/Gdsnt/BRMS/RecoveryReports') +
TOCCSID(1252) REPLACE(*YES)

As from this complete program which generates our BRMS reports and sticks
them off on two different windows servers (each in a different city).
/* Group Dekko Services, LLC */
/* ALL RIGHTS RESERVED. */
/* */
/* This program will create PDFs out of BRMS recovery reports */
/* */
/* */
/* Modification log: */
/* 08/04/11 by R.Berendt, CDP GDS,LLC */
/* Created */
/* */
/* */
PGM

DCL &QP1ARCY *CHAR 25 /* PDF file: step by step to full recovery
*/
DCL &QP1A2RCY *CHAR 26 /* PDF file: Volumes needed for above. */
DCL &SysName *CHAR 8 /* System Name */


/* +
| Retrieve the current system name +
*/
RTVNETA SYSNAME(&SysName)
CHGVAR &QP1ARCY ('/tmp/' *tcat &SysName *tcat '_QP1ARCY.PDF')
CHGVAR &QP1A2RCY ('/tmp/' *tcat &SysName *tcat '_QP12ARCY.PDF')

RMVLNK OBJLNK(&QP1ARCY)
MONMSG CPFA0A9 EXEC(DO) /* Object does not exist */
/* Remove message from cluttering joblog */
RCVMSG PGMQ(*SAME (*)) MSGTYPE(*EXCP) MSGKEY(*NONE) +
WAIT(0) RMV(*YES)
EndDo
RMVLNK OBJLNK(&QP1A2RCY)
MONMSG CPFA0A9 EXEC(DO) /* Object does not exist */
/* Remove message from cluttering joblog */
RCVMSG PGMQ(*SAME (*)) MSGTYPE(*EXCP) MSGKEY(*NONE) +
WAIT(0) RMV(*YES)
EndDo

OVRPRTF FILE(QP1ARCY) DEVTYPE(*AFPDS) TOSTMF(&QP1ARCY) WSCST(*PDF)
OVRPRTF FILE(QP1A2RCY) DEVTYPE(*AFPDS) TOSTMF(&QP1A2RCY) WSCST(*PDF)
STRRCYBRM OPTION(*SYSTEM) ACTION(*REPORT)
DLTOVR FILE(QP1ARCY)
DLTOVR FILE(QP1A2RCY)
/* +
| Copy PDF's out to Garrett and Kendallville servers for storage. +
*/
CPY OBJ(&QP1ARCY) TODIR('/qntc/Gdsnt/BRMS/RecoveryReports') +
TOCCSID(1252) REPLACE(*YES)
CPY OBJ(&QP1A2RCY) TODIR('/qntc/Gdsnt/BRMS/RecoveryReports') +
TOCCSID(1252) REPLACE(*YES)
CPY OBJ(&QP1ARCY) TODIR('/qntc/PTInt/BRMS/RecoveryReports') +
TOCCSID(1252) REPLACE(*YES)
CPY OBJ(&QP1A2RCY) TODIR('/qntc/PTInt/BRMS/RecoveryReports') +
TOCCSID(1252) REPLACE(*YES)


END:

ENDPGM

Rob Berendt