RE: SNDDST - scheduled send time?

Hi Mike -

Here's what we have done, created a program and command to set up a
submit job for the SNDDST.

========================================================================
Program:

 SENDMAIL:   PGM        PARM(&EMAIL &DATE &TIME &TXT)                   
             DCL        VAR(&DATE) TYPE(*CHAR) LEN(8)                   
             DCL        VAR(&TIME) TYPE(*CHAR) LEN(8)                   
             DCL        VAR(&EMAIL) TYPE(*CHAR) LEN(40)                 
             DCL        VAR(&TXT) TYPE(*CHAR) LEN(4000)                 
/* ****************************************************************** */
/* ***********************GLOBAL ERROR HANDLER*********************** */
/* ****************************************************************** */
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)                  
             DCL        VAR(&MSGKEY) TYPE(*CHAR) LEN(4)                 
             MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(ERROR))         
/* ****************************************************************** */

             SBMJOB     CMD(SNDDST TYPE(*LMSG) TOINTNET((&EMAIL)) +

                          DSTD(MESSAGE) LONGMSG(&TXT)) +

                          JOB(SENDMAIL) JOBQ(QPGMR) SCDDATE(&DATE) +

                          SCDTIME(&TIME)

             GOTO       CMDLBL(END)

 

 ERROR:      RCVMSG     PGMQ(*SAME) MSGTYPE(*ANY) MSGKEY(*NONE) +

                          WAIT(0) KEYVAR(&MSGKEY) MSGID(&MSGID)

             SNDPGMMSG  MSGID(&MSGID) MSGF(QCPFMSG)

 

 END:        ENDPGM   

========================================================================
========================================================================
Command:

             CMD        PROMPT('Send Email')                            
             PARM       KWD(EMAIL) TYPE(*CHAR) LEN(40) +                
                          CHOICE('YourEmail@xxxxxxxxxxxxxxx') +         
                          PROMPT('Enter Email address')                 
             PARM       KWD(DATE) TYPE(*CHAR) LEN(8) DFT(*CURRENT) +    
                          CHOICE('Date, *CURRENT') PROMPT('Enter Date') 
             PARM       KWD(TIME) TYPE(*CHAR) LEN(8) DFT(*CURRENT) +    
                          CHOICE('Time, *CURRENT') PROMPT('Enter Time') 
             PARM       KWD(TXT) TYPE(*CHAR) LEN(4000) +                
                          CHOICE('Text') PROMPT('Enter Text')


========================================================================


Hope this is helpful.  This command also works well with Management
Central monitors to send emails regarding CPU usage, job status, etc.

Regards,
 
Scott Ingvaldson
iSeries System Administrator
GuideOne Insurance Group     
                                       

-----Original Message-----
date: Wed, 16 Nov 2005 15:15:31 -0600
from: "Condon, Mike" <M1C@xxxxxxxxxxxxxxxxx>
subject: SNDDST - scheduled send time?

Is there an option on the SNDDST command (or some kind of workaround) to
set the actual "send" time of the message?
For example, form & execute the SNDDST command, but have it actually be
sent 4 hours or so later.