RE: Is there a way to SNDBRKMSG to only active work stations?

["alan shore" <SHOREA@xxxxxxxx>]

Much appreciated

>>> Winchester Terry <terry.winchester@raymondcorp.com> 03/15/02 07:31AM >>>
Well, here it is.  I hope its not too long. It could be
easily modified for other purposes...

/*-------------------------------------------------------------------*/
/* Program:        BRKMSG                                            */
/* Description:    Receive two parameters from any program and send  */
/*                 a message to any User using the QEZSNDMG API from */
/*                 the Operational Assistant menu.                   */
/*                                                                   */
/*                 &MSGTEXT  -  80 character message                 */
/*                 &USERID   -  10 character UserId to receive msg   */
/*                                                                   */
/*                 Notes:  -The message text passed to this program  */
/*                          should be limited to 80 chars.           */
/*                         -If the user has multiple sessions open,  */
/*                          each session will receive a message.     */
/*                         -Use *ALLACT as USERID to notify everyone */
/*-------------------------------------------------------------------*/
             PGM        PARM(&MSGTEXT &USERID)

             DCL        VAR(&MSGTYPE) TYPE(*CHAR) LEN(10) +
                          VALUE('*INFO')
             DCL        VAR(&DELMODE) TYPE(*CHAR) LEN(10) +
                          VALUE('*BREAK')
             DCL        VAR(&MSGTEXT) TYPE(*CHAR) LEN(80)
             DCL        VAR(&MSGLENG) TYPE(*CHAR) LEN(04) +
                          VALUE(X'00000050')
             DCL        VAR(&USERID) TYPE(*CHAR) LEN(10)
             DCL        VAR(&USRCNT) TYPE(*CHAR) LEN(04) +
                          VALUE(X'00000001')
             DCL        VAR(&MSGSENT) TYPE(*CHAR) LEN(04) +
                          VALUE(X'00000000')
             DCL        VAR(&FUNCREQ) TYPE(*CHAR) LEN(04) +
                          VALUE(X'00000000')
             DCL        VAR(&ERROR) TYPE(*CHAR) LEN(256) +
                          VALUE(X'00000100')
             DCL        VAR(&SHOWMSG) TYPE(*CHAR) LEN(01) VALUE('N')
             DCL        VAR(&REPLYMQ) TYPE(*CHAR) LEN(20)
             DCL        VAR(&NAMETYPE) TYPE(*CHAR) LEN(04) +
                          VALUE('*USR')

             CALL       PGM(QEZSNDMG) PARM(&MSGTYPE &DELMODE +
                          &MSGTEXT &MSGLENG &USERID &USRCNT +
                          &MSGSENT &FUNCREQ &ERROR &SHOWMSG +
                          &REPLYMQ &NAMETYPE)

 ENDJOB:     ENDPGM

> -----Original Message-----
> From: Dan Bale [mailto:dbale@samsa.com]
> Sent: Thursday, March 14, 2002 3:26 PM
> To: midrange-l@midrange.com
> Subject: RE: Is there a way to SNDBRKMSG to only active work stations?
>
>
> I'd be interested in the CL version!  Is it short enuf to
> post on the list?
> If not, send it to me privately.
>
> Thanks!
>
_______________________________________________
This is the Midrange Systems Technical Discussion (MIDRANGE-L) mailing list
To post a message email: MIDRANGE-L@midrange.com
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/cgi-bin/listinfo/midrange-l
or email: MIDRANGE-L-request@midrange.com
Before posting, please take a moment to review the archives
at http://archive.midrange.com/midrange-l.