RE: A program to get the IP address of the Internet connection.

             PGM        PARM(&EMAIL)
             DCL        VAR(&EMAIL) TYPE(*CHAR) LEN(4)
             DCL        VAR(&MSG) TYPE(*CHAR) LEN(132)
             DCL        VAR(&MSG2) TYPE(*CHAR) LEN(2000)
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)
             DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(14)
             DCL        VAR(&ERROR ) TYPE(*CHAR) LEN(3 )

             ADDLIBLE   CCALIB
             MONMSG     CPF0000

/* TRY TO ALLOCATE MESSAGE QUEUE, IF FAILS, ENDPROGRAM */

             ALCOBJ     OBJ((QTCP *MSGQ *EXCL)) WAIT(0)
             MONMSG     MSGID(CPF1002) EXEC(GOTO CMDLBL(ENDPROGRAM))
             DLCOBJ     OBJ((QTCP *MSGQ *EXCL))

/* WAIT HERE FOREVER FOR MESSAGE TCP8344 WITH IP ADDRESS */

 WAITAGAIN:  CHGVAR     VAR(&MSGID) VALUE('       ')
             RCVMSG     MSGQ(QTCP) WAIT(*MAX) RMV(*NO) MSG(&MSG) +
                          SECLVL(&MSG2) MSGDTA(&MSGDTA) MSGID(&MSGID)

             IF         COND(&MSGID *EQ 'TCP8344') THEN(GOTO +
                          CMDLBL(IPSTARTED))

             IF         COND(&MSGID *EQ 'TCP8343') THEN(GOTO +
                          CMDLBL(IPENDED)) /* Ended */

             GOTO       CMDLBL(WAITAGAIN)

/* SEND MESSAGE TO SYSOPR */

 IPSTARTED:
             SNDPGMMSG  MSGID(CPF9898) MSGF(QCPFMSG) MSGDTA(&MSG) +
                          TOUSR(*SYSOPR)

/* SEND EMAILS TO EVERYONE TO TELL THEM OF THE NEW ADDRESS */

             IF         (&EMAIL *EQ '*YES') THEN(DO)
             SNDDST     TYPE(*LMSG) +
                          TOINTNET((someone@somewhere.com)) +
                          DSTD(DESCRIPTION) MSG('Host IP Address +
                          is' *BCAT &MSGDTA) LONGMSG(' ') +
                          SUBJECT('Host now connected to the +
                          internet')
             ENDDO

             GOTO       CMDLBL(WAITAGAIN)

 IPENDED:
             SNDPGMMSG  MSGID(CPF9898) MSGF(QCPFMSG) MSGDTA(&MSG) +
                          TOUSR(*SYSOPR)

             GOTO       CMDLBL(WAITAGAIN)

 ENDPROGRAM: ENDPGM

Art Tostaine, Jr.
CCA, Inc.
Jackson, NJ 08527


-----Original Message-----
From: owner-midrange-l@midrange.com
[mailto:owner-midrange-l@midrange.com]On Behalf Of
mike@mcc-associates.com
Sent: Wednesday, November 24, 1999 10:52 AM
To: MIDRANGE-L@midrange.com
Subject: RE: A program to get the IP address of the Internet connection.
I would like to get a copy.

+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To subscribe to this list send email to MIDRANGE-L-SUB@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---