Here's a command that I wrapped around one of IBM's APIs to retrieve
Subsystem Info.  You can select the pool information you want to
interrogate.

This was from an abortive attempt to totally automate our weekend
operations.  After a noble effort, we realized that our environment changes
so rapidly, it's more productive to hire an operator for weekend operations
and leave the lights on.


--Paul E Musselman
PaulMmn@ix.netcom.com





>     ** Retrieve Subsystem Information.
>     **
>     **   COMMAND:   RTVSBSINF SBS(subsystemlib/subsystemname) +   <---+
>     **                        STATUS(status) +                        |
>     **                        SIGNON(filelib/filename) +              |
>     **                        SECONDLANG(library) +                   |
>     **                        MAXACT(maxactivejobs) +                 |
>     **                        CURRACT(currentlyactivejobs) +          |
>     **                        NBRPOOLS(number) +                      |
>     **                        POOLNBR(nbr) +         <----------------+
>     **                        POOLID(nbr) +                           |
>     **                        POOLNAME(name) +                        |
>     **                        POOLRES(reserved) +                     |
>     **                        POOLSIZE(nbr) +                         |
>     **                        POOLACTLVL(nbr)                         |
>     **                                                                |
>     **                             Information entered on command >---+
>     **                             All other fields returned by command
>     **
>     **  This program uses an API, but it does NOT require a User Space.
>     **
>     **
>     **                                    --Paul E Musselman   24 Sept 1996
>     **
>     **
>     **
>     E                    POOL       10 28
>     **
>     ISYSTEM     SDS
>     I                                     *STATUS  STATUS
>     I                                     *PARMS   PARMS
>     I
>     I
>     **
>     IERROR       DS
>     I                                    B   1   40ERRNOT
>     **
>     IMISC        DS
>     I                                    B   1   40LENDTA
>     I                                    B   5   80STRPOS
>     ICMDDS       DS
>     I                                        1  80 CMD
>     I                                       22  31 JQUEUE
>     I                                       14  34 JQLBNM
>     I                                       56  59 QCOUNT
>     I                                       81 160 CMD2
>     ISBSDTA      DS
>     I                                        1  10 SBNAME
>     I                                       11  20 SBLIB
>     IVARBLS      DS
>     I                                    B   1   40SUBDSL
>     IRCVVAR      DS
>     I                                    B   1   40OFFSET
>     I*                                             OFFSET TO LIST DATA
>SECTION
>     I                                    B   5   80LISIZE
>     I*                                             SIZE OF LIST DATA SECTION
>     I                                    B   9  120NUMENT
>     I*                                             NUMBER OF LIST ENTRIES
>     I                                    B  13  160LSTSIZ
>     I*                                             SIZE OF EACH ENTRY
>     IHEADER      DS
>     I                                        1  10 SBSNMU
>     I                                       11  20 SBSLBU
>     IQUSER       DS
>     I                                        1   5 QUSER5
>     I                                        1   8 QUSER8
>     I                                        1  10 QUSERX
>     ISUBDS       DS
>     I                                    B   1   40SUBYTE
>     I                                    B   5   80SUBAVL
>     I                                        9  18 SUBSYS
>     I                                       19  28 SUBLIB
>     I                                       29  38 SUBSTS
>     I                                       39  48 SUBDFN
>     I                                       49  58 SUBDFL
>     I                                       59  68 SUBLAN
>     I                                    B  69  720SUBMAX
>     I                                    B  73  760SUBACT
>     I                                    B  77  800SUBPOO
>     I                                       81 360 POOL
>     **
>     IPOOL1       DS
>     I                                    B   1   40SUBPID
>     I                                        5  14 SUBPNM
>     I                                       15  20 SUBPRS
>     I                                    B  21  240SUBPSZ
>     I                                    B  25  280SUBPAL
>     **
>     C           *ENTRY    PLIST
>     C                     PARM           SBSDTA
>     C                     PARM           STATUS 10
>     C                     PARM           SCNNAM
>     C                     PARM           SCNLIB
>     C                     PARM           LANGLB 10
>     C                     PARM           MAXACT  70
>     C                     PARM           CURACT  70
>     C                     PARM           NBRPOL  70
>     C                     PARM           POOL#   70
>     C                     PARM           POOLID  70
>     C                     PARM           POOLNM 10
>     C                     PARM           POOLRS  6
>     C                     PARM           POOLSZ  70
>     C                     PARM           POOLAC  70
>     **
>     C                     Z-ADD0         ERRNOT
>     C                     Z-ADD360.      SUBDSL
>     C*
>     C                     CALL 'QWDRSBSD'
>     C                     PARM           SUBDS
>     C                     PARM           SUBDSL
>     C                     PARM 'SBSI0100'FMT     8
>     C                     PARM           SBSDTA
>     C                     PARM           ERRNOT
>     **
>     C           POOL#     IFLE 0
>     C                     Z-ADD1.        POOL#
>     C                     END
>     **
>     C           POOL#     IFLE SUBPOO
>     C                     MOVEAPOOL,POOL#POOL1
>     C                     ENDIF
>     **
>     C           POOL#     IFGT SUBPOO
>     C*
>     C                     Z-ADD0         SUBPID
>     C                     MOVEL'INVALID 'SUBPNM
>     C                     MOVEL'XXXXXX'  SUBPRS
>     C                     Z-ADD0         SUBPSZ
>     C                     Z-ADD0         SUBPAL
>     C*
>     C                     ENDIF
>     **
>     C                     MOVE SUBSTS    STATUS 10
>     C                     MOVE SUBDFN    SCNNAM 10
>     C                     MOVE SUBDFL    SCNLIB 10
>     C                     MOVE SUBLAN    LANGLB 10
>     C                     Z-ADDSUBMAX    MAXACT  70
>     C                     Z-ADDSUBACT    CURACT  70
>     C                     Z-ADDSUBPOO    NBRPOL  70
>     C                     Z-ADDSUBPID    POOLID  70
>     C                     MOVE SUBPNM    POOLNM 10
>     C                     MOVE SUBPRS    POOLRS  6
>     C                     Z-ADDSUBPSZ    POOLSZ  70
>     C                     Z-ADDSUBPAL    POOLAC  70
>     **
>     C                     SETON                     LRRT
>     **
>
>
>
>
>-------------
>
> RTVSBSINF:  CMD        PROMPT('Retrieve Subsystem Information')
>
>/* CRTCMD CMD(UTLPRD/RTVSBSINF) PGM(UTLPRD/RTVSBSINFR)
>SRCFILE(UTLSRC/QCMDSRC) +
>     ALLOW(*BPGM *IPGM *BREXX *BMOD)
>*/
>
>             PARM       KWD(SBS) TYPE(SBS_LIB) MIN(1) +
>                          PROMPT('Subsystem Name')
> SBS_LIB:    QUAL       TYPE(*NAME) LEN(10) MIN(1)
>             QUAL       TYPE(*NAME) LEN(10) DFT(ALTQSYS) MIN(0) +
>                          PROMPT('Library Containing SBSD')
>
>             PARM       KWD(STATUS) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
>                          PROMPT('Subsystem Status')
>
>             PARM       KWD(SUBDFN) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
>                          PROMPT('Device File Name')
>
>             PARM       KWD(SUBDFL) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
>                          PROMPT('Device File Library')
>
>             PARM       KWD(LANGLB) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
>                          PROMPT('2ndary Language Library')
>
>             PARM       KWD(MAXACT) TYPE(*DEC) LEN(7 0) RTNVAL(*YES) +
>                          PROMPT('Maximum Active Jobs')
>
>             PARM       KWD(CURACT) TYPE(*DEC) LEN(7 0) RTNVAL(*YES) +
>                          PROMPT('Current Number of Active Jobs')
>
>             PARM       KWD(NBRPOL) TYPE(*DEC) LEN(7 0) RTNVAL(*YES) +
>                          PROMPT('Numbr of Defined Storage Pools')
>
>             PARM       KWD(POOL#) TYPE(*DEC) LEN(7 0) RTNVAL(*NO) +
>                          DFT(1) PROMPT('Following Fields for Pool#')
>
>             PARM       KWD(POOLID) TYPE(*DEC) LEN(7 0) RTNVAL(*YES) +
>                          PROMPT('Pool ID')
>
>             PARM       KWD(POOLNM) TYPE(*CHAR) LEN(10) RTNVAL(*YES) +
>                          PROMPT('Pool Name')
>
>             PARM       KWD(POOLRS) TYPE(*CHAR) LEN(6) RTNVAL(*YES) +
>                          PROMPT('*** reserved ***')
>
>             PARM       KWD(POOLSZ) TYPE(*DEC) LEN(7 0) RTNVAL(*YES) +
>                          PROMPT('Pool Size')
>
>             PARM       KWD(POOLAC) TYPE(*DEC) LEN(7 0) RTNVAL(*YES) +
>                          PROMPT('Pool Activity Level')

--------------------------------


+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to "MIDRANGE-L@midrange.com".
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---


This thread ...

Replies:

Follow On AppleNews
Return to Archive home page | Return to MIDRANGE.COM home page

This mailing list archive is Copyright 1997-2020 by midrange.com and David Gibbs as a compilation work. Use of the archive is restricted to research of a business or technical nature. Any other uses are prohibited. Full details are available on our policy page. If you have questions about this, please contact [javascript protected email address].