Re: Database File Attributes

["David Gibbs" <devdmg@xxxxxxxxxxxxxxxxxxxxxxxx>]

On 26 Aug 97 at 20:33, telsci wrote:

> Better yet, I have created a utility to change all of the files to
> re-use deleted records *YES. It's written in COBOL (thank you Rear
> Admiral Grace Murray Hopper R.I.P) but I could compile it as low as
> V2R3 if that's what you need.  Let me know if you want it. 

I had this laying around in my bag of tricks... it's CL, so everyone 
should be able to use it.

/* This program will change all eligible files in a single library */
/* to reuse deleted records.                                        */
/* Simply call the program with the library name you wish to        */
/* process as the parameter.  It's up to you to ensure that no      */
/* files in the library are currently being used.                   */

/* This program was written and copyright 1995,1997 by David Gibbs. */
/* This program is granted to the public domain so long as credit   */
/* is given where due.                                              */

             PGM        PARM(&LIB)                                    

             DCL        VAR(&LIB) TYPE(*CHAR) LEN(10)                 
             DCLF       FILE(QAFDPHY)                                 

             DSPFD      FILE(&LIB/*ALL) TYPE(*ATR) OUTPUT(*OUTFILE) + 
                          FILEATR(*PF) OUTFILE(QTEMP/QAFDPHY)         

             OVRDBF     FILE(QAFDPHY) TOFILE(QTEMP/QAFDPHY)           

NEXTFILE:                                                             
             RCVF                                                     
             MONMSG     MSGID(CPF0864) EXEC(GOTO CMDLBL(ENDFILE))     

             IF         COND(&PHRUSE = 'N' *AND &PHFTYP = 'P' *AND +  
                          &PHDTAT = 'D') THEN(DO)                     
             CHGPF      FILE(&PHLIB/&PHFILE) REUSEDLT(*YES)           
             ENDDO                                                    

             GOTO       CMDLBL(NEXTFILE)                    
                                                            
ENDFILE:                                                    
             DLTOVR     FILE(QAFDPHY)                       
                                                            
             ENDPGM                                         


david

--

David Gibbs
Sr. Software Engineer
Silvon Software
Westmont, IL
(630) 655-3313 x6479
http://www.silvon.com
mailto:david.gibbs@silvon.com

Opinions expressed are strictly my own and do 
not necessarily reflect those of my employer

... You'll only see your obstacles each time 
    you take your eyes off of your goal.

                   -- DMRoth
+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to "MIDRANGE-L@midrange.com".
| To unsubscribe from this list send email to MAJORDOMO@midrange.com
|    and specify 'unsubscribe MIDRANGE-L' in the body of your message.
| Questions should be directed to the list owner/operator: david@midrange.com
+---