|
midrange.com
Until such time as the PTF is available, you can use the attached
programs.
NoSniffCL must be the program called by the routing entry in your
interactive subsystem(s). This CL presumes that your current routing
program is QCMD. Obviously, you need to make provision for whatever your
subsystem currently uses. In other words, if you're not using QCmd for
one or more of your routings, you'll need a copy of this CL that uses
the program your subsystem(s) use. You may need multiple of these CL
programs if you have multiple programs specified in the subsystem(s).
The program makes the buffer area look like it would when you signoff by
placing the indicator bytes, system name and subsystem name inside.
Gary Guthrie
/* =============================================================== */
/* = Program... NoSniffCL = */
/* =============================================================== */
Pgm
Call Pgm( YourLib/NOSniffRpg )
TfrCtl QSys/QCmd
EndPgm
* ===================================================================
* = Program... NoSniffRPG =
*
===================================================================
H DftActGrp( *No ) BndDir( 'QC2LE' )
D GetIntInfo PR * ExtProc( '_PCOPTR' )
D SetSpacePtr PR * ExtProc( 'setsppfp' )
D pItem 16 Value
D RtvNetAttr PR ExtPgm( 'QWCRNETA' )
D pNetInfo 32
D pNetInfoLen 10I 0
D pNbrAttr 10I 0
D pAttrNames 10
D pAPIError 8
D RtvJobInfo PR ExtPgm( 'QUSRJOBI' )
D pJobInfo 72
D pJobInfoLen 10I 0
D pFormat 8
D pQualJobName 26
D pIntJobID 16
D IntInfo DS Based( IntInfoPtr )
D UFCBPtr * Overlay( IntInfo : 433 )
D Subsystem 16 Overlay( IntInfo : 529 )
D UFCBInfo DS Based( UFCBInfoPtr )
D BufferPtr * Overlay( UFCBInfo: 17 )
D BufferInfo DS Based( BufferInfoPtr )
D CleanItUp 20 Overlay( BufferInfo : 1 )
D NetInfo DS 32
D SystemName 8 Overlay( NetInfo : 25 )
D NetInfoLen S 10I 0 Inz( %Size( NetInfo ) )
D NbrAttr S 10I 0 Inz( 1 )
D AttrNames S 10 Inz( 'SYSNAME' )
D APIError S 8 Inz( X'0000000000000000')
D JobInfo DS 72
D SubsystemName 10 Overlay( JobInfo : 63 )
D JobInfoLen S 10I 0 Inz( %Size( JobInfo ) )
D Format S 8 Inz( 'JOBI0200' )
D QualJobName S 26 Inz( '*' )
D IntJobID S 16 Inz( *Blank )
C Eval IntInfoPtr = GetIntInfo
C Eval IntInfoPtr = SetSpacePtr( Subsystem )
C Eval UFCBInfoPtr = UFCBPtr
C Eval BufferInfoPtr = BufferPtr
C CallP RtvNetAttr( NetInfo :
C NetInfoLen :
C NbrAttr :
C AttrNames :
C APIError )
C CallP RtvJobInfo( JobInfo :
C JobInfoLen :
C Format :
C QualJobName :
C IntJobID )
C Eval CleanItUp = '10' +
C SystemName +
C SubsystemName
C Eval *InLR = *On
edfishel@us.ibm.com wrote:
>
> IBM is working on a solution to the password sniffing problem. PTFs should
> be available soon for all supported releases. For product 5769SS1 (OS/400),
> the V4R3 PTF number is SF62894, the V4R4 PTF is SF62895, and the V4R5 PTF
> is SF62896.
>
> After you apply the PTF for your system you will need to activate it by
> terminating and then restarting all subsystems that perform interactive
> work. Doing an IPL is one way to do this. Since your passwords may have
> been compromised, after applying and activating the fix, you may wish to
> change the passwords on your systems.
>
> Ed Fishel
> IBM Rochester
>
> +---
> | This is the MI Programmers Mailing List!
> | To submit a new message, send your mail to MI400@midrange.com.
> | To subscribe to this list send email to MI400-SUB@midrange.com.
> | To unsubscribe from this list send email to MI400-UNSUB@midrange.com.
> | Questions should be directed to the list owner/operator: dr2@cssas400.com
> +---
+---
| This is the MI Programmers Mailing List!
| To submit a new message, send your mail to MI400@midrange.com.
| To subscribe to this list send email to MI400-SUB@midrange.com.
| To unsubscribe from this list send email to MI400-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: dr2@cssas400.com
+---
As an Amazon Associate we earn from qualifying purchases.
This mailing list archive is Copyright 1997-2024 by midrange.com and David Gibbs as a compilation work. Use of the archive is restricted to research of a business or technical nature. Any other uses are prohibited. Full details are available on our policy page. If you have questions about this, please contact [javascript protected email address].
Operating expenses for this site are earned using the Amazon Associate program and Google Adsense.
