× The internal search function is temporarily non-functional. The current search engine is no longer viable and we are researching alternatives.
As a stop gap measure, we are using Google's custom search engine service.
If you know of an easy to use, open source, search engine ... please contact support@midrange.com.



Susan,

Here is a sample RPG usage of the API:

     D*
     D* Compile with:
     D* CRTBNDRPG PGM(xxxxxxx) DFTACTGRP(*NO) BNDDIR(QC2LE)
     D*
     DGetPath          PR              *   EXTPROC('Qp0lGetPathFromFileID')
     D                                 *   VALUE
     D                               10i 0 VALUE
     D                               16
     D*
     DErrno            pr              *   extproc('__errno')
     D*
     D* Note that Buffer is too small at 50 bytes for most applications,
     D* but is used here simply for demonstration purposes (with DSPLY).
     D*
     DBuffer           S             50
     D*
     D* Get FileID from Audit Journal entry (see Security Reference)
     D*
     DFileID           S             16    INZ(x'00000000000000007CE1D725-
     D                                     00002EF7')
     D*
     Derrno_val        S             10I 0 based(errno_ptr)
     Derrno_ptr        S               *
     DReturnPtr        S               *
     C*
     C* Get Path
     C*
     C                   eval      ReturnPtr = GetPath(%ADDR(Buffer)
     C                                                : %SIZE(Buffer)
     C                                                : FileID)
     C                   if        ReturnPtr <> *NULL
     C*
     C* If successful:
     C*
     C     Buffer        dsply
     C                   else
     C*
     C* If failure, display Errno value (see QSYSINC/SYS ERRNO and
     C* QCLE/H ERRNO for value descriptions)
     C*
     C     'NOT FOUND'   dsply
     C                   eval      errno_ptr = Errno
     C     errno_val     dsply
     C                   endif
     C*
     C                   move      '1'           *inlr
     C                   return

Hope it helps,
Bruce Vining

>
>Does anyone have sample code on how to use the Qp01GetPathFromFileID()
>API?  Is it possible to use this API from ILE RPG?
>
>Susan McPartland
>Bently Nevada Corp
>Minden, NV
>

+---
| This is the Midrange System Mailing List!
| To submit a new message, send your mail to MIDRANGE-L@midrange.com.
| To unsubscribe from this list send email to MIDRANGE-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---


As an Amazon Associate we earn from qualifying purchases.

This thread ...


Follow On AppleNews
Return to Archive home page | Return to MIDRANGE.COM home page

This mailing list archive is Copyright 1997-2024 by midrange.com and David Gibbs as a compilation work. Use of the archive is restricted to research of a business or technical nature. Any other uses are prohibited. Full details are available on our policy page. If you have questions about this, please contact [javascript protected email address].

Operating expenses for this site are earned using the Amazon Associate program and Google Adsense.