Re: Example of executing a URL from a CLP

Michael - how cool is that - I got it to work. Thank you MUCH!

-----Original Message-----
From: web400-bounces@xxxxxxxxxxxx [mailto:web400-bounces@xxxxxxxxxxxx]
On Behalf Of Michael Ryan
Sent: Tuesday, January 20, 2009 7:50 AM
To: Web Enabling the AS400 / iSeries
Subject: Re: [WEB400] Example of executing a URL from a CLP

Here's one....It gets the IP address of the incoming connection and then
uses runrmtcmd to talk to the client. Drop me a line if you have any
questions.

PGM PARM(&URL)

DCL VAR(&URL) TYPE(*CHAR) LEN(128)
DCL VAR(&CMD) TYPE(*CHAR) LEN(256)
DCL VAR(&DEVICENAME) TYPE(*CHAR) LEN(10)
DCL VAR(&IPADDR) TYPE(*CHAR) LEN(15)
DCL VAR(&WINPGM) TYPE(*CHAR) LEN(10) VALUE('start')
DCL VAR(&SERVICE) TYPE(*CHAR) LEN(10) +
VALUE('http://')

/******************************/
/* Parameters for QDCRDEVD */
/******************************/
DCL VAR(&RECEIVER) TYPE(*CHAR) LEN(892)
DCL VAR(&RCVRLENGTH) TYPE(*CHAR) LEN(4)
DCL VAR(&FORMATNAME) TYPE(*CHAR) LEN(8) +
VALUE('DEVD0600') /* The format for +
display devices */
DCL VAR(&ERRORCODE) TYPE(*CHAR) LEN(4) +
VALUE(X'00000000') /* Use normal error +
handling */
RTVJOBA JOB(&DEVICENAME)

/******************************/
/* Set length of receiver */
/******************************/
CHGVAR VAR(%BIN(&RCVRLENGTH)) VALUE(892)

/******************************/
/* Get device info */
/******************************/
CALL PGM(QDCRDEVD) PARM(&RECEIVER &RCVRLENGTH +
&FORMATNAME &DEVICENAME &ERRORCODE)

CHGVAR VAR(&IPADDR) VALUE(%SST(&RECEIVER 878 15))

CHGVAR VAR(&CMD) VALUE(&WINPGM *BCAT &SERVICE *TCAT +
&URL)

RUNRMTCMD CMD(&CMD) RMTLOCNAME(&IPADDR *IP) +
RMTUSER(SOMEUSER) RMTPWD('somepwd')
MONMSG MSGID(CPF91CC) EXEC(SNDPGMMSG MSGID(CPF9898) +
MSGF(QCPFMSG) MSGDTA('Unable to start web +
page'))

ENDPGM: ENDPGM


On Tue, Jan 20, 2009 at 8:28 AM, Don Cavaiani <dcavaiani@xxxxxxxxxxxxx>
wrote:

Anyone have a simple example of doing this?

Don F. Cavaiani
IT Manager
Amerequip Corp.
920-894-7063

"It's amazing what you can accomplish if you don't care who gets the
credit." Harry S. Truman



--
This is the Web Enabling the AS400 / iSeries (WEB400) mailing list To
post a message email: WEB400@xxxxxxxxxxxx To subscribe, unsubscribe,
or change list options,
visit: http://lists.midrange.com/mailman/listinfo/web400
or email: WEB400-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives at
http://archive.midrange.com/web400.

--
This is the Web Enabling the AS400 / iSeries (WEB400) mailing list To
post a message email: WEB400@xxxxxxxxxxxx To subscribe, unsubscribe, or
change list options,
visit: http://lists.midrange.com/mailman/listinfo/web400
or email: WEB400-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives at
http://archive.midrange.com/web400.