Maybe consider specifying a command to run at initial connection to set your RDi job's library list.
We use a custom program to make it easy to set "commonly used" library lists.
To start: I right-click one of my connections, then select "Properties",
On the "Properties for xxx" window, on the Left, select "Subsystems"
From the " Subsystems" pane to the Right, in "Initial command:" I specify something like:
CALL PGM(liba/setlibl) PARM('xx' ' ')
For us "liba/setlibl" is a custom CL which uses the first, two character parm to select a library list and
current library from a local file and then do a CHGLIBL.
The second one character parm is a return parm that is ignored
CL source included below in case anyone is interested.
HTH
CL source:
PGM PARM(&CMPFIL &RTNCDE)
DCLF FILE(XXINITL2)
DCL VAR(&CMPFIL) TYPE(*CHAR) LEN(2) /* Input +
company file group */
DCL VAR(&DIVNBRP) TYPE(*CHAR) LEN(2) /* Division +
number - parameter */
DCL VAR(&APLENVIRNP) TYPE(*CHAR) LEN(1) /* +
Application environment - parameter */
DCL VAR(&RTNCDE) TYPE(*CHAR) LEN(4) /* Return +
code - parameter */
DCL VAR(&LIBL) TYPE(*CHAR) LEN(275) /* Library +
list */
DCL VAR(&CMD) TYPE(*CHAR) LEN(500) /* Command +
string */
DCL VAR(&MSGID) TYPE(*CHAR) LEN(7) /* Message +
identifier */
DCL VAR(&MSG) TYPE(*CHAR) LEN(79)
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
/* Global monitor message. If error received, go to error routine. */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
MONMSG MSGID(CPF0000) EXEC(GOTO CMDLBL(ERROR))
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
/* Initialize the program return code to blank. */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
CHGVAR VAR(&RTNCDE) VALUE(' ')
/* IF COND(&CMPFIL *EQ ' ') THEN(DO) +
CHGVAR VAR(&CMPFIL) VALUE('S1') +
ENDDO +
END */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
/* Position/read the XXINITL file to get the record for the division */
/* number and application environment requested. */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
READ_FILE: OVRDBF FILE(XXINITL2) POSITION(*KEY 1 *N &CMPFIL)
RCVF
IF COND(&CMPFIL *NE &COMFIL) THEN(GOTO +
CMDLBL(ERROR))
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
/* Change the library list and current library using the library */
/* list library names for the division and application */
/* environment requested. */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
CHGVAR VAR(&LIBL) VALUE(&LIBLLIB01 *BCAT &LIBLLIB02 +
*BCAT &LIBLLIB03 *BCAT &LIBLLIB04 *BCAT +
&LIBLLIB05 *BCAT &LIBLLIB06 *BCAT +
&LIBLLIB07 *BCAT &LIBLLIB08 *BCAT +
&LIBLLIB09 *BCAT &LIBLLIB10 *BCAT +
&LIBLLIB11 *BCAT &LIBLLIB12 *BCAT +
&LIBLLIB13 *BCAT &LIBLLIB14 *BCAT +
&LIBLLIB15 *BCAT &LIBLLIB16 *BCAT +
&LIBLLIB17 *BCAT &LIBLLIB18 *BCAT +
&LIBLLIB19 *BCAT &LIBLLIB20 *BCAT +
&LIBLLIB21 *BCAT &LIBLLIB22 *BCAT +
&LIBLLIB23 *BCAT &LIBLLIB24 *BCAT +
&LIBLLIB25) /* Form library list */
IF COND(&CURLIB *EQ ' ') THEN(CHGVAR +
VAR(&CURLIB) VALUE('*CRTDFT '))
CHGVAR VAR(&CMD) VALUE('CHGLIBL LIBL(' *CAT &LIBL +
*TCAT ') CURLIB(' *CAT &CURLIB *TCAT ')')
CALL PGM(QCMDEXC) PARM(&CMD 500) /* Change +
library list and current library */
/* IF COND(&CMPFIL *EQ 'S1') THEN(DO) +
CHGVAR VAR(&CMPFIL) VALUE(' ') +
ENDDO +
END */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
/* Initialize the program return code to good. Go to exit. */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
CHGVAR VAR(&RTNCDE) VALUE('GOOD')
GOTO CMDLBL(EXIT)
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
/* Error routine. Set return code equal to the last four bytes of */
/* the message identifier. */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
ERROR: RCVMSG MSGTYPE(*EXCP) RMV(*NO) MSGID(&MSGID)
CHGVAR VAR(&RTNCDE) VALUE(%SST(&MSGID 4 4))
CHGVAR VAR(&MSG) VALUE('* LIBL LIST NOT CHANGED. +
INVALID FILE GROUP.')
SNDPGMMSG MSG(&MSG) TOPGMQ(*PRV)
MONMSG MSGID(CPF0000)
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
/* End of program. */
/* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
EXIT: RETURN
ENDPGM
-----Original Message-----
From: WDSCI-L [mailto:wdsci-l-bounces@xxxxxxxxxxxx] On Behalf Of Vernon Hamberg
Sent: Tuesday, August 18, 2015 9:57 AM
To: Rational Developer for IBM i / Websphere Development Studio Client for System i & iSeries
Subject: Re: [WDSCI-L] How can I remove a library from a library filter?
Good point, Kurt
Many kinds of filters -
1. Library list filter - all you can do is give it a name, its contents are your *LIBL
- You can remove libraries from the library list here, and add to the library list 2. Library filter - these CAN specify *LIBL or *ALLUSR or *USRLIBL - the various special values for any library parameter of a command, as well as (and in addition?) a list of individual libraries
- You can add items here to your library list (items not already on the library list, right?)
- You cannot remove anything from your library list here - only from a library list filter
Random thought - maybe you can use an object filter with *LIB as the
object type - no idea - and why would you? :)
HTH
Vern
On 8/18/2015 10:17 AM, Kurt Anderson wrote:
A temporary solution is to right-click the library and select "Remove From Library List." That will only apply to the active connection. Once you disconnect and reconnect (or close and re-open RDi), the library will be back.
To my knowledge you can't "Change" a library list filter. It's grayed out for me.
I have a couple connections setup with a specific JOBD so the library list is as I want it (mostly) for those connections. I'm not sure if that's a path you can take or not. Having connections is also nice so when I do modify a library list on one connection via the filter, it's not also affecting other connections.
Kurt Anderson
Sr. Programmer/Analyst - Application Development, Service Delivery
Platform
-----Original Message-----
From: WDSCI-L [mailto:wdsci-l-bounces@xxxxxxxxxxxx] On Behalf Of Jeff
Young
Sent: Monday, August 17, 2015 4:06 PM
To: Rational Developer for IBM i / Websphere Development Studio Client
for System i & iSeries <wdsci-l@xxxxxxxxxxxx>
Subject: Re: [WDSCI-L] How can I remove a library from a library filter?
What type of filter is it?
You should be able to right click on the filter name and select Change.
You will see a list on the left of all items in your filter. You can remove an item from the filter by Left click/delete.
this removes it from the filter only, not the system.
Jeff Young
Sr. Programmer Analyst
On Mon, Aug 17, 2015 at 4:00 PM, DFreinkel
<dfreinkel@xxxxxxxxxxxxxxxxx>
wrote:
I have several libraries in my one filter and need to remove the
unwanted ones from the filter and not the system.
I cannot find a way to accomplish this.
Using the delete option physically removes the library.
TIA.
Darryl Freinkel.
Sent from my iPad
--
This is the Rational Developer for IBM i / Websphere Development
Studio Client for System i & iSeries (WDSCI-L) mailing list To post
a message email: WDSCI-L@xxxxxxxxxxxx To subscribe, unsubscribe, or
change list options,
visit: http://lists.midrange.com/mailman/listinfo/wdsci-l
or email: WDSCI-L-request@xxxxxxxxxxxx Before posting, please take a
moment to review the archives at http://archive.midrange.com/wdsci-l.
--
This is the Rational Developer for IBM i / Websphere Development
Studio Client for System i & iSeries (WDSCI-L) mailing list To post a
message email: WDSCI-L@xxxxxxxxxxxx To subscribe, unsubscribe, or
change list options,
visit: http://lists.midrange.com/mailman/listinfo/wdsci-l
or email: WDSCI-L-request@xxxxxxxxxxxx Before posting, please take a
moment to review the archives at http://archive.midrange.com/wdsci-l.
--
This is the Rational Developer for IBM i / Websphere Development Studio Client for System i & iSeries (WDSCI-L) mailing list To post a message email: WDSCI-L@xxxxxxxxxxxx To subscribe, unsubscribe, or change list options,
visit:
http://lists.midrange.com/mailman/listinfo/wdsci-l
or email: WDSCI-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives at
http://archive.midrange.com/wdsci-l.
midrange.com
