RE: Is it possible to have a dspf window with 2 subfiles?

[Frederik Vanderhaeghe <Frederik.Vanderhaeghe@xxxxxxxxxxxxxxx>]

Thanks for the input! It works!

-----Oorspronkelijk bericht-----
Van: RPG400-L [mailto:rpg400-l-bounces@xxxxxxxxxxxxxxxxxx] Namens Brian Parkins
Verzonden: zaterdag 13 augustus 2022 1:28
Aan: RPG programming on IBM i
Onderwerp: Re: Is it possible to have a dspf window with 2 subfiles?

For completeness and just to elaborate, what I think you mean 
(correctly) is that output/input from the Display is done via the 
Control Format. So the statements should be:

WRITE SFLCTL8
EXFMT SFLCTL7
READ  SFLCTL7

The Subfile (SFL) formats describe the layout of the (temporary) data so use READ/WRITE operations as if handling a database file.

Brian.

On 12/08/2022 15:07, Frederik Vanderhaeghe via RPG400-L wrote:
> Hello,
>
> EXFMT on a subfile is not possible...
>
> Frederik Vanderhaeghe
>
>
> -----Oorspronkelijk bericht-----
> Van: RPG400-L [mailto:rpg400-l-bounces@xxxxxxxxxxxxxxxxxx] Namens Carel via RPG400-L
> Verzonden: vrijdag 12 augustus 2022 15:28
> Aan: rpg400-l@xxxxxxxxxxxxxxxxxx
> CC: Carel
> Onderwerp: Re: Is it possible to have a dspf window with 2 subfiles?
>
> Been a while:
>
> First write to the 2 SFLs then
>
> WRITE Scherm8
> EXFMT Scherm7
> READ Scherm8
>
> And put OVERLAY in SFLCTL7 too
>
> Op 12-8-2022 om 14:53 schreef Frederik Vanderhaeghe via RPG400-L:
> > Hello,
> >
> > In our programming we are always using windows...
> > Now I would like to have a window with 2 subfiles, is that possible?
> >
> > What I have for the moment:
> >        A          R SCHERM7                   SFL
> >        A            S7VRWP    R        O  6  1REFFLD($$VRWP)
> >        A                                      COLOR(WHT)
> >        A            S7VRWV    R        O    +2REFFLD($$VRWV)
> >        A                                      COLOR(WHT)
> >        A            S7VOM1    R        O    +2REFFLD($$VOM1)
> >        A                                      COLOR(WHT)
> >        A            S7VOM2    R        O    +2REFFLD($$VOM2)
> >        A                                      COLOR(WHT)
> >        A            S7VRWN    R        H      REFFLD($$VRWN)
> >        A            S7OFNR    R        H      REFFLD($$OFNR)
> >        A          R SFLCTL7                   SFLCTL(SCHERM7)
> >        A                                      RTNCSRLOC(&S7RECI &S7FLDI
> >        A                                      &S7POSI)
> >        A  49                                  CSRLOC(S7LINU S7POSU)
> >        A N70                                  SFLDSPCTL
> >        A  71                                  SFLDSP
> >        A  70                                  SFLCLR
> >        A                                      CF03
> >        A                                      SFLSIZ(200)
> >        A                                      SFLPAG(5)
> >        A                                      SFLCSRRRN(&RELRCD)
> >        A  74                                  SFLEND(*MORE)
> >        A N74                                  ROLLUP(72)
> >        A                                      WINDOW(1 5 25 119)
> >        A                                      WDWBORDER((*COLOR WHT))
> >        A  30                                  WDWTITLE((*TEXT ' Goedkeuren mits..-
> >        A                                      . ') (*COLOR WHT))
> >        A                                      CHGINPDFT
> >        A            S7RRN          3  0H      SFLRCDNBR
> >        A            RELRCD         5S 0H
> >        A                                  1  1'Algemene vrijstelling:'
> >        A            S7ALVR    R        B    +1REFFLD($$VRYS)
> >        A                                      COLOR(WHT)
> >        A                                      EDTCDE(2)
> >        A                                  3  1'Extra vrijstelling voor waarborg:'
> >        A            S7WRBG    R        B    +1REFFLD($$WRBG)
> >        A                                      COLOR(WHT)
> >        A            S7WRBV    R   44        +1REFFLD($$WRBV)
> >        A                                      COLOR(BLU)
> >        A                                    +3'Vrijstelling:'
> >        A            S7VRWB    R        B    +1REFFLD($$VRYS)
> >        A                                      COLOR(WHT)
> >        A                                      EDTCDE(2)
> >        A                                  4  1'F1=Alle voorwerpen selecteren'
> >        A                                      COLOR(BLU)
> >        A                                  5  1'Voorwerp                   Omschri-
> >        A                                      jving 1                            -
> >        A                                      Omschrijving 2                     -
> >        A                                           '
> >        A                                      DSPATR(RI)
> >        A                                      COLOR(GRN)
> >        A            S7LINU         3S 0H
> >        A            S7POSU         3S 0H
> >        A            S7LINI         3S 0H
> >        A            S7POSI         4S 0H
> >        A            S7FLDI        10A  H
> >        A            S7RECI        10A  H
> >        A            S7VRWN        15S 0H
> >        A          R SCHERM8                   SFL
> >        A            S8VRWP    R        O 16  1REFFLD($$VRWP)
> >        A                                      COLOR(WHT)
> >        A            S8VRWV    R        O    +2REFFLD($$VRWV)
> >        A                                      COLOR(WHT)
> >        A            S8VOM1    R        O    +2REFFLD($$VOM1)
> >        A                                      COLOR(WHT)
> >        A            S8VOM2    R        O    +2REFFLD($$VOM2)
> >        A                                      COLOR(WHT)
> >        A            S8VRWN    R        H      REFFLD($$VRWN)
> >        A            S8OFNR    R        H      REFFLD($$OFNR)
> >        A          R SFLCTL8                   SFLCTL(SCHERM8)
> >        A                                      RTNCSRLOC(&S8RECI &S8FLDI
> >        A                                      &S8POSI)
> >        A  49                                  CSRLOC(S8LINU S8POSU)
> >        A N75                                  SFLDSPCTL
> >        A  76                                  SFLDSP
> >        A  75                                  SFLCLR
> >        A                                      SFLSIZ(200)
> >        A                                      SFLPAG(5)
> >        A                                      SFLCSRRRN(&RELRCD8)
> >        A  77                                  SFLEND(*MORE)
> >        A N77                                  ROLLUP(72)
> >        A                                      OVERLAY
> >        A                                      WINDOW(SFLCTL7)
> >        A                                      CHGINPDFT
> >        A            S8RRN          3  0H      SFLRCDNBR
> >        A            RELRCD8        5S 0H
> >        A                                 15  1'Voorwerp                   Omschri-
> >        A                                      jving 1                            -
> >        A                                      Omschrijving 2                     -
> >        A                                               %   '
> >        A                                      DSPATR(RI)
> >        A                                      COLOR(GRN)
> >        A            S8LINU         3S 0H
> >        A            S8POSU         3S 0H
> >        A            S8LINI         3S 0H
> >        A            S8POSI         4S 0H
> >        A            S8FLDI        10A  H
> >        A            S8RECI        10A  H
> >        A            S8VRWN        15S 0H
> >        A          R DUMMY
> >        A                                      ASSUME
> >        A                                  2  2' '
> >
> >
> > It shows SFLCTL7 with subfile SCHERM7, but it doesn't show SFLTCL8 with SCHERM8...
> > I'm not getting any errors anymore when executing the program.
> > I first write SFLCTL7, then SCHERM7, then SFLCTL8, then SCHERM8 and then exfmt SFLCTL7.
> >
> > Thanks in advance for advice!
> >
> > Frederik Vanderhaeghe