Re: free format replace I-specs and plist

[Scott Klement <rpg400-l@xxxxxxxxxxxxxxxx>]

Arco,

There is no free-format equivalent to PLIST.  Probably the best solution 
would be to write an open access version of UNIXCMD.

But, aside from the PLIST, everything else can be done with free format. 
 You can replace any I/O specs with data structures.

For example, this is EXAMPLE4 converted to free format:

        dcl-f UNIX special(1000) pgmname('UNIXCMD')
                   plist(unixparm) usropn;
        dcl-f QSYSPRT printer(132) usage(*output);
        dcl-s cmd char(5000);
        dcl-ds record len(1000) end-ds;
        dcl-ds outrec len(132) end-ds;

     C     UNIXPARM      PLIST
     C                   PARM                    cmd

        cmd = 'cd /tmp; ls';
        open UNIX;

        read UNIX record;
        dow not %eof(UNIX);
           outrec = record;
           write QSYSPRT outrec;
           read UNIX record;
        enddo;

        close UNIX;
        *inlr = *on;




On 11/18/2016 3:22 AM, Arco Simonse wrote:
> Hi all,
>
> Maybe a dumb question, but here it goes...
>
> We're using Scott's great UNIXCMD tool in our programs, and we want convert
> our program to "fully free".
> Replacement of the file declaration is no problem:
>
>        dcl-f UNIX special(1000) pgmname('UNIXCMD') plist(unixparm) usropn;
>        dcl-s cmd char(5000);
>
> But how do I replace these specs?
>
>      IUNIX      NS
>      I                                  1 1000  Record
>
>
>      C     UNIXPARM      PLIST
>      C                   PARM                    CMD
>
>
> Many thanks!
> Best regards,
> -Arco