Re: Anyway to use SAVEPOINTS in a transaction using RPG RLA?

Below an example

** --------------------------------------------------------------
H dftactgrp(*no) actgrp(*new)
H option(*srcstmt : *nodebugio)
FItems uf e k disk Commit UsrOpn
F Rename(Items : ItemsF)
** --------------------------------------------------------------
DQcmdExc PR EXTPGM('QCMDEXC')
D 256A Const options(*varsize)
D 15P 5 Const
D Cmd s 256A Varying
D Key s 6S 0
** --------------------------------------------------------------
/free
Cmd = 'STRCMTCTL LCKLVL(*CS) NFYOBJ(Items (*FILE))';
QcmdExc(cmd:%len(cmd));
Open Items;

// First Update
Key = 1;
Chain Key Items;
Descr = 'First update';
Update ItemsF;

// Second Update
Exec SQL SAVEPOINT A ON ROLLBACK RETAIN CURSORS;
Chain Key Items;
Descr = 'Second Update';
Update ItemsF;

// Rollback the last update
Exec SQL Rollback Work to Savepoint A;

// Rollback all update
Exec SQL Rollback; // or ROLBCK

Close Items;
Cmd = 'ENDCMTCTL';
QcmdExc(cmd:%len(cmd));
*inlr = *on;
/end-free