RE: Current User Job Attribute and Current User in Program Status Data Structure

They are the same. This can be easily proven with a program like this:

D beThatUser PR ExtPgm('BETHATUSER')
D user 10 Const
D pwd 10 Const

D beThatUser PI
D user 10 Const
D pwd 10 Const

D getHandle PR ExtProc('QsyGetProfileHandle')
D profHandle Like(handle)
D userProf Const Like(user)
D password Const Like(pwd)
D pwdLen 10I 0 value Options(*NoPass)
D ccsid 10I 0 value Options(*NoPass)
D errStruct 65535 Options(*VarSize: *Nopass)

D getHandleNoPwd PR ExtProc('QsyGetProfileHandleNoPwd ')
D profHandle Like(handle)
D profHandle Like(handle)
D userProf Const Like(user)
D pwdValue Const Like(pwd)
D errStruct 65535 Options(*VarSize: *Nopass)

D setHandle PR ExtProc('QsySetToProfileHandle')
D profHandle Like(handle)
D errStruct 65535 Options(*VarSize: *Nopass)

D rlsHandle PR ExtProc('QsyReleaseProfileHandle')
D profHandle Like(handle)
D errStruct 65535 Options(*VarSize: *Nopass)

D qcmd PR ExtPgm('QCMD')

/Include LUVPGMSRC,LUVPROTO

D pgmStsDS SDS
D currentUser 358 367
D myUSEC DS LikeDS(luvUSEC) Inz
D handle S 12
D myHandle S Like(handle)

/Free
myUSEC.bytesProvided = %Size(myUSEC) ;
getHandleNoPwd(handle: '*CURRENT': '*NOPWD': myUSEC) ;
If myUSEC.QUSBAVL = *Zero ;
getHandle(handle: user: pwd
: %Len(pwd)
: -1
: myUSEC) ;
EndIF ;
If myUSEC.QUSBAVL = *Zero ;
setHandle(handle: myUSEC) ;
if myUSEC.QUSBAVL = *Zero ;
dsply currentUser ;
qcmd() ;
EndIF ;
setHandle(myHandle: myUSEC) ;
rlsHandle(handle: myUSEC) ;
rlsHandle(myHandle: myUSEC) ;
EndIF ;
*INLR = *On ;
If myUSEC.bytesAvailable > *Zero ;
sendEscape(myUSEC.QUSEI: myUSEC.QUSED01) ;
EndIF ;
Return ;
/End-free


Dennis Lovelady
http://www.linkedin.com/in/dennislovelady
--
"A cynic is a man who knows the price of everything and the value of
nothing."
-- Oscar Wilde

-----Original Message-----
From: rpg400-l-bounces@xxxxxxxxxxxx [mailto:rpg400-l-
bounces@xxxxxxxxxxxx] On Behalf Of Birgitta Hauser
Sent: Wednesday, December 15, 2010 8:33 AM
To: 'RPG programming on the IBM i / System i'
Subject: Current User Job Attribute and Current User in Program Status
Data Structure

Hi,



Can someone enlighten me! We have some discussions.

I used the current user out of the program status data structure
(position
358) instead of calling a CL Program that does nothing else than
RTVJOBA
CURUSER(&X).

My colleague insists I have to call this CL program because it is not
the
same.



Can someone enlighten me? Is the current user (job attribute) the same
as
the current user within the PGMSDS or not?



Mit freundlichen Grüßen / Best regards



Birgitta Hauser



"Shoot for the moon, even if you miss, you'll land among the stars."
(Les
Brown)

"If you think education is expensive, try ignorance." (Derek Bok)

"What is worse than training your staff and losing them? Not training
them
and keeping them!"



--
This is the RPG programming on the IBM i / System i (RPG400-L) mailing
list
To post a message email: RPG400-L@xxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/mailman/listinfo/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives
at http://archive.midrange.com/rpg400-l.