Re: Converting Unix Jan 01 1970 UTC epoch datetime stamp to iSeries EST datetime stamp

Errr...

Scott Klement wrote:

I recently posted an example of doing exactly what you're trying to do.
Here's a link:
http://www.systeminetwork.com/isnetforums/showthread.php?t=49068

Actually that thread is the OPPOSITE of what you wnated to do. Here's code that does what you want to do:

*+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
* Convert Unix timestamp to RPG timestamp
*
* Call this with the data returned by stat() or Qp0lGetAttr
* convert to an RPG timestamp field.
*+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
P Unix2Rpg B
D Unix2Rpg PI Z
D UnixTime 10U 0 value

D CEEUTCO PR
D Hours 10I 0
D Mins 10I 0
D Secs 8F
D fc 12A options(*omit)

D Epoch c z'1970-01-01-00.00.00'
D TimeZone s 10I 0 static inz(-1)
D Hours s 10I 0
D Mins s 10I 0
D Secs s 8F
D retval s Z

/free

if (TimeZone = -1);
CEEUTCO(Hours: Mins: Secs: *omit);
TimeZone = secs;
endif;

retval = Epoch;
retval = retval + %seconds(UnixTime) + %seconds(TimeZone);
return retval;

/end-free
P E