Just call the Retrieve Job Information API directly from your RPG module.
Assuming you have the QSYSINC library installed (option 13 of i5/OS),
here's a quick example to display the current output queue values:
d/copy qsysinc/qrpglesrc,qusrjobi
d/copy qsysinc/qrpglesrc,qusec
dRtvJobI pr extpgm('QUSRJOBI')
d RcvVar 1 options(*varsize)
d LenRcvVar 10i 0 const
d RcvVarFmt 8 const
d JobName 26 const
d IntJobID 16 const
d QUSEC likeds(QUSEC) options(*nopass)
d Reset 1 const options(*nopass)
dWait s 1
/free
// Set error processing to send exceptions
QUSBPRV = %size(QUSEC);
// Get output queue for current job
RtvJobI( QUSI030000 :%size(QUSI030000) :'JOBI0300' :'*' :' ' :QUSEC);
if QUSOL <> *blanks;
dsply ('The output queue is: ' + %trimr(QUSOL) + '/' + QUSON)
' ' Wait;
else;
dsply ('The ouput queue is: ' + QUSON) ' 'Wait;
endif;
*inlr = *on;
return;
/end-free
Hope this helps,
Bruce Vining
"Andy Hautamaki" <ahautamaki@xxxxxxxxxxxxxxx>
Sent by: rpg400-l-bounces@xxxxxxxxxxxx
04/24/2007 08:06 AM
Please respond to
RPG programming on the AS400 / iSeries <rpg400-l@xxxxxxxxxxxx>
To
"RPG400-L@xxxxxxxxxxxx" <RPG400-L@xxxxxxxxxxxx>
cc
Subject
RTVJOBA OUTQ()
Is there a way other then from calling a CL program to get the job
attributes for the outq? 'RTVJOBA OUTQ(&OUTQ)'
I have a rpg module where depending on the job attributes for the outq
being
used I'm possibly going to do a special override to use another output
queue.
Is there a way by using QCMDEXC to receive back a value? In other words
build the RTVJOBA OUTQ(&OUTQ) then execute the QCMDEXC and get the value
for
the out queue in my RPG module?
Thanks
Andy
midrange.com
