Re: C-Function gmtime() within ILE RPG -- RPG400-L

Hi Burkhard,

we have a Database with a Unix Time Field and I want to use
the Unix Function gmtime() I coded the following RPGLE.
But with these Parameter I get a wrong result in MYTime Structure.

There are two bugs in your program that are causing it to fail. ButI'll explain those in a moment.

But, I wonder why you want to use gmtime()? You're programming in RPG,not C!! Why not take advantage of RPG's date and time functions? It'svery easy to convert a Unix time field to an RPG timestamp field. Justdo this:


     D EPOCH           C                   z'1970-01-01-00.00.00.000000'
     D myTS            s               Z
          .
          .
          Unixtime = 1173954308 ;
          myTS = EPOCH + %seconds(UnixTime);

Now that you've done that, you have a timestamp field that you can usewith all of RPG's time operations -- and that makes it very easy tomanipulate. (You can also retrieve your system's UTC offset if you wantto, and use that to convert it to local time.)

But, if for some reason you really want to make it work with thegmtime() function, that's certainly doable.


There are 2 big problems with your code:

1) Your prototype for gmtime() is wrong.

2) You're trying to assign a memory address to a data structure,
    rather than to the pointer that the structure is based on.
    (Bob Cozzi already pointed this second bug out.)

Here's what you have for a prototype:

D gmtime          Pr              *   ExtProc('gmtime')
D  t_time                       10I 0 Value

However, if you look at the C prototype (it's in QSYSINC/H,TIME) itlooks like this:

   struct tm *gmtime    ( const time_t * );

Can you see the difference? The RPG code passes the parameter by VALUE-- but the C code passes it by read-only reference. Since the API isexpecting to receive it by reference, it gets very confused when youpass it by VALUE!! To fix this bug, change your prototype to look likethis:


  D gmtime          Pr              *   ExtProc('gmtime')
  D  t_time                       10I 0 const

See? Now the parameter is passed by "const reference" (i.e. read-onlyreference).

The other problem, as Bob already pointed out, is that you're assigningthe address to the data structure name instead of the pointer that it'sbased on. The way you have it coded, it shouldn't even compile, whichmakes me think that this was a mistake you made when you posted yourcode, rather than a mistake that's actually on your system.


Anyway, here's what you have:

      Unixtime = 1173954308 ;
      mytime = gmtime(Unixtime) ;


Here's what it should be:

       Unixtime = 1173954308 ;
       tm = gmtime(Unixtime) ;

After making these two changes, your program should work fine. (It doeson my system!) But, again... I think using RPG's date/time support(as I demonstrated earlier) is much simpler, provides a result that'seasier to work with, and will be more maintainable down the road.