Re: RPG Socket API help?

On Wed, 16 Aug 2006, Robert Upshall wrote:

Whenever I set the port to be non-blocking, the connect fails.  Have you
ever experienced that before?

So... how do you fix it?

a) Create the socket
b) Put it in non-blocking
c) Connect() -- this'll always return -1
d) Check errno -- if it's EINPROGRESS, all is well.  If not, something has
    gone wrong with the connect() API.
e) Wait for the connection to complete.  To do that, call the select() API
    and put the descriptor in the "write set".  If the socket isn't
    writable in your timeout period, then the connection timed out.
    If the socket IS writable, either it succeeded or an error occurred.
f) Use the getsockopt() API with SOL_SOCKET and SO_ERROR to find out if
    an error occurred while it was connecting.  If an error did occur,
    use the err number returned by getsockopt() (instead of errno) to
    report the problem.

      *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
      * tconnect(): Connect w/timeout
      *
      *      host = (input) host to connect to
      *      port = (input) port number to connect to
      *   maxsecs = (input) maximum seconds to wait for connect
      *
      * Returns a connected socket, or -1 upon failure
      *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
     P tconnect        B                   export
     D tconnect        PI            10I 0
     D    host                      255A   const
     D    port                        5U 0 value
     D    maxsecs                    10I 0 value
     D    ErrMsg                     80A

     D ipaddr          s             10U 0
     D sock            s             10I 0
     D flags           s             10I 0
     D connto          ds                  likeds(sockaddr_in)
     D rc              s             10I 0
     D writeset        s                   like(fdset)
     D rcsize          s             10I 0
     D timeout         ds                  likeds(timeval)
     D errno           s             10I 0 based(p_errno)

      /free

         // ------------------------------------------------
         //   Look up host
         // ------------------------------------------------

         ipaddr = inet_addr(%trimr(host));
         if (ipaddr = INADDR_NONE);
              p_hostent = gethostbyname(%trimr(host));
              if (p_hostent = *NULL);
                  errMsg = 'host not found!';
              else;
                  ipaddr = h_addr;
              endif;
         endif;

         // ------------------------------------------------
         //   Create a socket and put it in non-blocking
         //   mode.
         // ------------------------------------------------

         sock = socket(AF_INET: SOCK_STREAM: IPPROTO_IP);
         if (sock = -1);
             p_errno = sys_errno();
             ErrMsg = %str(strerror(errno));
             return -1;
         endif;

         flags = fcntl(sock: F_GETFL);
         flags = %bitor(flags: O_NONBLOCK);
         fcntl(sock: F_SETFL: flags);

         // ------------------------------------------------
         //   Start the connection process
         //   connect will always return -1, but if all
         //   is well, errno will be set to EINPROGRESS
         // ------------------------------------------------

         connto = *allx'00';
         connto.sin_family = AF_INET;
         connto.sin_addr   = ipaddr;
         connto.sin_port   = port;

         rc = connect(sock: %addr(connto): %size(connto));
         p_errno = sys_errno();
         if (rc = -1 and errno<>EINPROGRESS);
            ErrMsg = %str(strerror(errno));
            callp close(sock);
            return -1;
         endif;

         // ------------------------------------------------
         //  Wait for connection to complete
         // ------------------------------------------------

         FD_ZERO(writeSet);
         FD_SET(sock: writeSet);

         timeout.tv_sec  = maxsecs;
         timeout.tv_usec = 0;

         rc = select( sock+1
                    : *NULL
                    : %addr(writeSet)
                    : *NULL
                    : %addr(timeout) );
         if (rc = -1);
            p_errno = sys_errno();
            errMsg = %str(strerror(errno));
            callp close(sock);
            return -1;
         endif;

         if (rc = 0);
            errMsg = 'Time out before connection completed.';
            callp close(sock);
            return -1;
         endif;

         // ------------------------------------------------
         //  Check if an error occurred
         // ------------------------------------------------

         rc = 0;
         rcsize = %size(rc);
         getsockopt(sock: SOL_SOCKET: SO_ERROR: %addr(rc): rcsize);

         if (rc <> 0);
            ErrMsg = %str(strerror(rc));
            callp close(sock);
            return -1;
        endif;

         // ------------------------------------------------
         //  Hurray!  Connection is completed!
         // ------------------------------------------------
        return sock;
      /end-free
     P                 E