Re: Data Areas -- RPG400-L

My experience with data areas is to define a UDS ex. for a 10 alpha data
area:

    D DMARTXDATE     UDS                  DTAARA
    D  ODREVDT                      10A

You're mixing two different techniques! There are two completely separateways to read a data area in RPG, and although it's possible to combinethem, it's not necessary to.


Here are the two ways:

a) Using the old style "UDS" data area.  When you put a U in front of the

letters "DS", the data area will automatically be read & locked when yourprogram starts, and written back to disk/unlocked when the program ends.


It's not necessary to use the DTAARA keyword with a UDS data area.

UDS data areas must be created as TYPE(*CHAR)

b) a DTAARA (or *DTAARA DEFINE) data area. This is just a variable -- anyvariable -- defined with the DTAARA keyword. You can then read this dataarea with the IN and OUT op-codes. You control when the data area is readand/or written using these op-codes.

In this case, you can put the DTAARA keyword in a data structure if youwant many subfields in the data area (in which case, it again has to beTYPE(*CHAR)) or you can put it on a standalone field def in a D-spec, inwhich case it can be numeric as well.

In any case DTAARA keyword can be given a data area name as a parameter sothe data area name does not have to match the variable name.

If the DTAARA keyword is given a parameter that starts with *VAR, then thename can be a variable (which is what you want) and it can be calculatedanytime before the data area is read.

--

In your example, you've used UDS and DTAARA on the same definition, soit'll be automatically read when your program starts, but you can stilluse IN and OUT with it... I guess you could call that the "best of bothworlds" but frankly, it seems to confuse more people than anything else.

The problem with the new program is that the data area won't be in the
library list at runtime.  I need to resolve the library name at runtime,
then retrieve the contents of the data area, and proceed based on these
contents.

The problem with using UDS in your current scenario is that you don't WANTthe data area to be read as the program starts, because you want to beable to calculate the filename first. No big problem... just don't useUDS. Use DTAARA with *VAR, and calculate the name prior to using the INop-code.

I don't want to make a CL/RPG pair.  I looked at the QWCRDTAA
API, but I wonder if this is really necessary for this task.  Can I
accomplish the task without using this API?

Rest assured that this can be done very easily in RPG, and withoutresorting to an additional CL program or a nasty API.


     D CoolName        s             21A
     D ODREVDT         s             10A   dtaara(*Var:CoolName)

      /free

          CoolName = 'TONYLIB/DMARTXDATE';
          IN *LOCK ODREVDT;
          ODREVDT = '12/13/2014';
          OUT ODREVDT;

          *inlr = *on;
      /end-free

In the above example, the data area's name is stored in the CoolNamevariable. You can use whatever calculations are necessary to populatethat variable prior to calling the IN op-code.

In the above example, I demonstrate not only reading the data area, butalso updating it. If you don't need to change the contents of the dataarea, you can omit the "*LOCK" on the IN op-code, and you can omit the OUTop-code completely. (Unlike UDS, the IN op-code won't lock the data areaunless you specify *LOCK)