RE: Finding Severity level of a mesage from a RPG pgm

Hi Paul,

You can use the QMHRTVM API with the format RTVM0200 or higher. 

Here's an extraction from what I use.

Best regards, 
Arco Simonse


      // Retrieve Message Description API Prototype
     d QMHRTVM         PR                  extpgm('QMHRTVM')
     d MsgInfo...
     d                             4000A
     d MsgInfoLength...
     d                                9B 0
     d FormatName...
     d                                8A
     d MsgID...
     d                                7A
     d QualifiedFileName...
     d                               20A
     d ReplacementData...
     d                               40A
     d ReplacementDataLength...
     d                                9B 0
     d SubstituteVariables...
     d                               10A
     d ReturnFormatControls...
     d                               10A
     d ErrorCode...
     d                                9B 0
     d RetrieveOption...
     d                               10A
     d ConvertToCCSID...
     d                                9B 0
     d ReplacementDataCCSID...
     d                                9B 0


      // Define Variables for QMHRTVM API call: Return variables
     d MsgInfo         DS          4000    qualified
     d  Data                   1   4000
     d  MsgSeverity                   9B 0 overlay(Data :9)
      // and all the other fields you need


      // Define Variables for QMHRTVM API call: Required Input variables
     d MsgInfoLength...
     d                 S              9B 0
     d FormatName...
     d                 S              8A
     d MsgID...
     d                 S              7A
     d QualifiedFileName...
     d                 S             20A
     d ReplacementData...
     d                 S             40A
     d ReplacementDataLength...
     d                 S              9B 0
     d SubstituteVariables...
     d                 S             10A
     d ReturnFormatControls...
     d                 S             10A
     d ErrorCode...
     d                 S              9B 0
     d RetrieveOption...
     d                 S             10A
     d ConvertToCCSID...
     d                 S              9B 0
     d ReplacementDataCCSID...
     d                 S              9B 0


      /free

        // Load API parameter fields
        MsgInfo               = *BLANKS;
        MsgInfoLength         = 4000;
        MsgID                 = 'YOURMSG'
        QualifiedFileName     = 'YOURMSGF  *LIBL     '
        ReplacementData       = *blanks;
        ReplacementDataLength = %len(ReplacementData);
        FormatName            = 'RTVM0200';
        SubstituteVariables   = '*YES';
        ReturnFormatControls  = '*YES';
        RetrieveOption        = '*MSGID';
        ErrorCode             = 0;
        ConvertToCCSID        = 0;
        ReplacementDataCCSID  = 0;

        // Retrieve message description
        callp(e)  QMHRTVM( MsgInfo
                         : MsgInfoLength
                         : FormatName
                         : MsgID
                         : QualifiedFileName
                         : ReplacementData
                         : ReplacementDataLength
                         : SubstituteVariables
                         : ReturnFormatControls
                         : ErrorCode
                         : RetrieveOption
                         : ConvertToCCSID
                         : ReplacementDataCCSID
                         );

        // No error, then pick return variables
        if not %error;
           YourSeverity = MsgInfo.MsgSeverity;
        // Else set error text
        else;
           // error handling
        endif;
      /end-free
 
DISCLAIMER:
This message contains information that may be privileged or
confidential and is the property of C.Meijer B.V. It is intended only for the 
person to whom it is addressed. If you are not the intended recipient, you are 
not authorized to read, print, retain, copy,disseminate, distribute, or use 
this message or any part thereof. If you
receive this message in error, please notify the sender immediately and delete 
all copies of this message. 

This footnote also confirms that this email message has been swept by the 
presence of computer viruses