RE: Clearing a PF from an RPG program -- RPG400-L

× The internal search function is temporarily non-functional. The current search engine is no longer viable and we are researching alternatives.
As a stop gap measure, we are using Google's custom search engine service.
If you know of an easy to use, open source, search engine ... please contact support@midrange.com.

Great, thanks to everyone who responded.

Brian.

-----Original Message-----
From: Alan Campin [mailto:Alan.Campin@xxxxxxx] 
Sent: Wednesday, June 22, 2005 4:09 PM
To: RPG programming on the AS400 / iSeries
Subject: RE: Clearing a PF from an RPG program

>> If CLRPF is quicker, what is the procedure to call it from RPG?

d ExecuteCommand...                            
d                 pr              n            
d  PR_CommandToExecute...                      
d                            32767    Varying  
d                                     Value    

/Free                                      

   If Not ExecuteCommand('CLRPFM FILE(<YourFile>)');
     <Your logic if it doesn't work.>
   EndIf;                                      
/End-Free 

or just

   ExecuteCommand('CLRPFM FILE(<YourFile>)');

Just return.
 *--------------------------------------------------                 
 * Procedure name: ExecuteCommand                                    
 * Purpose:        Execute a command                                 
 * Returns:                                                          
 * Parameter:      InCommand => Incoming command                     
 *--------------------------------------------------                 
p ExecuteCommand  b                                                  
d                 pi              n                                  
d  InCommand                 32767    Varying                        
d                                     Value                          

d ExecuteQCMDEXC...                                                  
d                 pr                  ExtPgm('QCMDEXC')              
d  PR_CommandToExecute...                                            
d                            32767    Options(*VarSize)              
d                                     Const                          
d  PR_CommandLength...                                               
d                               15p 5 Const                          
d  PR_IGCProcessControl...                                           
d                                3    Options(*NoPass)
d                                     Const       
 /Free                                            

    Monitor;                                      
       ExecuteQCMDEXC(InCommand:%Len(InCommand)); 
    On-Error;                                     
       Return '1';                                
    EndMon;                                       
    Return '0';                                   

 /End-Free                                        
p                 e

This mailing list archive is Copyright 1997-2024 by midrange.com and David Gibbs as a compilation work. Use of the archive is restricted to research of a business or technical nature. Any other uses are prohibited. Full details are available on our policy page. If you have questions about this, please contact [javascript protected email address].

Operating expenses for this site are earned using the Amazon Associate program and Google Adsense.