RE: Using LIKE Operator in SQLRPGLE ?

[rob@xxxxxxxxx]

Was your comparison a varying length string?

select * from rob/myfilex
ABC
A
B
end of data

     D count           S              5B 0
     d test1           s              5a
     d test2           s              1a
     d test3           s              5a   varying
     d response        s              1a

      /free
       test1='A';
       count=*zeros;
      /end-free

     C/EXEC SQL
     C+ SELECT COUNT(*) INTO :count
     C+ FROM myfilex
     C+ WHERE mychar like :test1 || '%'
     C/END-EXEC
      /free
       dsply 'test1 concat %';
       dsply sqlstt;
       dsply count ' ' response;
       test1='A%';
       count=*zeros;
      /end-free
     C/EXEC SQL
     C+ SELECT COUNT(*) INTO :count
     C+ FROM myfilex
     C+ WHERE mychar like :test1
     C/END-EXEC
      /free
       dsply 'test1%';
       dsply sqlstt;
       dsply count ' ' response;
       test2='A';
       count=*zeros;
      /end-free
     C/EXEC SQL
     C+ SELECT COUNT(*) INTO :count
     C+ FROM myfilex
     C+ WHERE mychar like :test2 || '%'
     C/END-EXEC
      /free
       dsply 'test2 concat %';
       dsply sqlstt;
       dsply count ' ' response;
       test3='A';
       count=*zeros;
      /end-free
     C/EXEC SQL
     C+ SELECT COUNT(*) INTO :count
     C+ FROM myfilex
     C+ WHERE mychar like :test3 || '%'
     C/END-EXEC
      /free
       dsply 'test3 concat %';
       dsply sqlstt;
       dsply count ' ' response;
       *inlr=*on;
      /end-free

DSPLY  test1 concat %
DSPLY  00000 
DSPLY      1 

DSPLY  test1%
DSPLY  00000 
DSPLY      1 

DSPLY  test2 concat %
DSPLY  00000 
DSPLY      2 

DSPLY  test3 concat %
DSPLY  00000 
DSPLY      2 

Rob Berendt
-- 
Group Dekko Services, LLC
Dept 01.073
PO Box 2000
Dock 108
6928N 400E
Kendallville, IN 46755
http://www.dekko.com