Re: Monitor

[Scott Klement <rpg400-l@xxxxxxxxxxxxxxxx>]

> I am looking at the opcode MONITOR.  In a program, I am forcing a divide 
> by zero, and then expecting to see the excpt_nbr or excpt_id with a 
> value of 00102 or 0102.  In debug, they both show values of of *Blanks.
>
> What am I not doing?

It's hard to say what you're "not doing" since you didn't post any code, 
and I don't know what 'excpt_nbr' and 'excpt_id' are.

I usually use the %STATUS BIF to get the error number that occurs.  So I 
might code something lihe the following:

     D x               s             10I 0 inz(0)
     D status          s             10I 0 inz(0)

      /free

          monitor;
            x = 1 / x;
          on-error;
            status = %status;
            dsply status;
          endmon;

          *inlr = *on;

      /end-free

In that case, it'll display 102 on the screen.

Of course, you can also tell the MONITOR op-code to only look for a 
particular status code...  that way, if something you didn't expect 
occurs, it won't be "caught" by the on-error operation.

For example:

     D x               s             10I 0 inz(0)

      /free

          monitor;
            x = 1 / x;
          on-error 102;
            dsply 'Divide by zero';
          endmon;

          *inlr = *on;

      /end-free

The DSPLY operations in the above example are for demonstration purposes 
only.  Please do not use DSPLY in a finished program!