Re: Unusual error that I cannto figure out

[Jonathan Mason <masonjo1@xxxxxxxxxxxxxxxx>]

Hi Douglas

You are telling the program to display the subfile by setting on the SFLDSP 
indicator, *IN51, but you haven't written any records to the subfile.  If you 
don't yet have any records to write then just display the subfile control 
record.  I personally use separate indicators for the SFLDSP and SFLDSPCTL 
keywords, for example:

     A  51                                  SFLDSP        
     A  52                                  SFLDSPCTL     
     A N52                                  SFLCLR        
                                                          
      * ---------------------                             
      * R P G   S N I P P E T                             
      * ---------------------                             
                                                          
      * Named Indicators...                               
     D IndPtr          s               *   Inz(%Addr(*IN))
     D IndAra          Ds            99    Based(IndPtr)  
     D  SflDsp                51     51                   
     D  SflDspCtl             52     52                   
                                                          
      * Clear the subfile...                              
     C                   Eval      SflDsp = *Off          
     C                   Eval      SflDspCtl = *Off       
     C                   Write     RecCtl                 
                                                          
      * Write Subfile control only...             
     C                   Eval      SflDsp = *Off  
     C                   Eval      SflDspCtl = *On
     C                   Exfmt     RecCtl         
                                                  
      * Display Subfile records...                
     C                   Eval      SflDsp = *On   
     C                   Eval      SflDspCtl = *On
     C                   Exfmt     RecCtl         

You would still need to add a section where you load the subfile record, 
increasing the RRN by one as you write the record.

Hope that helps a little

All the best

Jonathan
www.astradyne-uk.com




-----Original message-----
From: "Douglas W. Palme" dpalme@xxxxxxxxxxxxxxxxxxxxx
Date: Mon, 22 Nov 2004 17:19:25 +0000
To: RPG programming on the AS400 / iSeries rpg400-l@xxxxxxxxxxxx
Subject: Unusual error that I cannto figure out

> I am working with subfiles and thought I had this down, but unfortunately I 
> am getting an unusual error message when I try to run the program.  Here is 
> the dds for the subfile and the program that is calling it. 
> 
> All I am trying to do at the moment is display the subfile to the screen.
> 
> The error message is the following, which I have never seen before:
> 
> Job 182784/DPALME/QPADEV0010 started on 11/22/04 at 11:45:21 in subsystem BA
> Session or device error occurred in file SUBFILE (C G D F).                 
> 
> Application error.  RNX1255 unmonitored by JDEAL at statement 0000000014,...
> 
> Any suggestions or comments would be appreciated.
> 
> Douglas
> 
> 
> DDS:
>  A*%%TS  SD  20041122  114708  DPALME      REL-V5R2M0  5722-WDS            
>  A*%%EC                                                                    
>  A                                      DSPSIZ(24 80 *DS3)                 
>  A          R RECSFL                    SFL                                
>  A*%%TS  SD  20041122  114708  DPALME      REL-V5R2M0  5722-WDS            
>  A            NOTES         75   B  3  5                                   
>  A          R RECCTL                    SFLCTL(RECSFL)                     
>  A*%%TS  SD  20041122  114708  DPALME      REL-V5R2M0  5722-WDS            
>  A                                      CA03(03)                           
>  A  51                                  SFLDSP                             
>  A  51                                  SFLDSPCTL                          
>  A  52                                  SFLCLR                             
>  A                                      SFLSIZ(0016)                       
>  A                                      SFLPAG(0015)                       
>  A                                  1 24'THIS IS THE CONTROL RECORD HEADER'
> 
> PGM:
> 
>  *program: subfiler                                      
> Fsubfile   CF   E             workstn                    
> F                                     sfile(recsfl:rrn)  
> Drrn              s              3  0                    
> C                   DOU       *IN03                      
> C                   EVAL      *IN52 = *ON                
> C                   WRITE     RECCTL                     
> C                   EVAL      *IN52 = *OFF               
> C                   EVAL      *IN51 = *ON                
> C                   EXFMT     RECCTL                     
> C                   ENDDO                                
> C                   EVAL      *INLR = *ON                


Jonathan Mason
www.astradyne-uk.com