RE: How retrieve remote IP address

This is how I get the IP of the current session.  You could change the
subprocedure to receive a workstation rather than pull the current one from
the program status data structure:

     D                SDS
     D  gWorkStation         244    253A
     D  gUserID              254    263A

     P getCurrentIP    B                   Export
       //------------------------------------------------------------------
       //   <getCurrentIP> Get current session IP address
       //
       //   @Usage: IPAddr 15A = getCurrentIP()
       //------------------------------------------------------------------
     D getCurrentIP    Pi            15A

       // Stand Alones
     D Error           S            256A

       // Data Structures
     D DevicDescr      DS          1024
     D  IPAddr               877    891A

       // API Prototypes
     D getDeviceDesc   PR                  ExtPgm('QDCRDEVD')
     D  Reciever                   1024A
     D  RecvLen                       5I 0 Const
     D  FormatName                    8A   Const
     D  DeviceName                   10A   Const
     D  Error                       256A

      /Free
       getDeviceDesc(DevicDescr : 1024 : 'DEVD0600' : gWorkStation : Error);
       Return IPAddr;
      /End-Free

     P getCurrentIP   E

-----Original Message-----
From: vinciamo@xxxxxx [mailto:vinciamo@xxxxxx] 
Sent: Monday, May 05, 2003 5:33 AM
To: rpg400-l@xxxxxxxxxxxx
Subject: How retrieve remote IP address

Is there an api for retrieving remote ip address of a session connected
by Client Access Express(telnet)??

Thanks in advance!

Vincenzo Amoruso
System Project s.r.l.
Andria(BA) - Italy



_______________________________________________
This is the RPG programming on the AS400 / iSeries (RPG400-L) mailing list
To post a message email: RPG400-L@xxxxxxxxxxxx
To subscribe, unsubscribe, or change list options,
visit: http://lists.midrange.com/mailman/listinfo.cgi/rpg400-l
or email: RPG400-L-request@xxxxxxxxxxxx
Before posting, please take a moment to review the archives
at http://archive.midrange.com/rpg400-l.