Re: Detach Journal Receiver

["Charlie Massoglia" <cmassoglia@xxxxxxxxxxx>]

The following CL program will detach and delete the current journal receiver
generating a new one.

Hope this helps.

/*                                                                  */
/*  CHGJRNRCVC - CHANGE JOURNAL RECEIVER AND DELETE OLD RECEIVERS   */
/*  06 FEB 90 - CHARLES L. MASSOGLIA                                */
/*                                                                  */
/*  COPYRIGHT 1990 MPH, INC., OKEMOS, MICHIGAN USA                  */
/*  ALL RIGHTS RESERVED                                             */

             PGM       PARM(&JRN &JRNLIB)

/*  DECLARE INCOMING PARAMETERS  */
             DCL        VAR(&JRN) TYPE(*CHAR) LEN(10)
             DCL        VAR(&JRNLIB) TYPE(*CHAR) LEN(10)

/*  DECLARE PROGRAM VARIABLES  */
             DCL        VAR(&INQMSGRPY) TYPE(*CHAR) LEN(10)
             DCL        VAR(&JRNRCVNAME) TYPE(*CHAR) LEN(10)
             DCL        VAR(&JRNRCVLIB) TYPE(*CHAR) LEN(10)
             DCL        VAR(&MSGID) TYPE(*CHAR) LEN(7)
             DCL        VAR(&MSGDTA) TYPE(*CHAR) LEN(80)

/*  CHANGE JOURNAL RECEIVER FOR JOURNAL &JRN IN LIBRARY &JRNLIB  */
             CHGJRN     JRN(&JRNLIB/&JRN) JRNRCV(*GEN)
             MONMSG     MSGID(CPF0000)

/*  CHECK FOR DETACHED JOURNAL TO DELETE  */
 RCV:        RCVMSG     MSGQ(*PGMQ) MSGTYPE(*INFO) MSGDTA(&MSGDTA) +
                          MSGID(&MSGID)
             IF         COND(&MSGID *EQ ' ') THEN(GOTO +
                          CMDLBL(ENDRCV))
             IF         COND(&MSGID *NE CPF7020 +
                          *OR %SST(&MSGDTA 21 10) *EQ ' ' +
                          *OR %SST(&MSGDTA 21 10) *EQ  '*N') +
                          THEN(GOTO CMDLBL(RCV)) +
                          /*  CPF7020 = JOURNAL RECEIVER DETACHED  */

/*  GOT JOURNAL TO DELETE - RETRIEVE DETACHED  */
/*  JOURNAL RECEIVER NAME AND LIBRARY          */
             CHGVAR     VAR(&JRNRCVNAME) VALUE(%SST(&MSGDTA 21 10))
             CHGVAR     VAR(&JRNRCVLIB) VALUE(%SST(&MSGDTA 31 10))

/*  SAVE JOB'S INQUIRY MESSAGE STATUS AND CHANGE TO *DFT  */
             RTVJOBA    INQMSGRPY(&INQMSGRPY)
             CHGJOB     INQMSGRPY(*DFT)

/*  DELETE JOURNAL RECEIVER  */
             DLTJRNRCV  JRNRCV(&JRNRCVLIB/&JRNRCVNAME)
             MONMSG     MSGID(CPF0000)

/*  RESTORE JOB'S INQUIRY MESSAGE STATUS  */
             CHGJOB     INQMSGRPY(&INQMSGRPY)

/*  DONE WITH JOURNAL  */
 ENDRCV:

/*  DONE  */
 END:        ENDPGM


Charles L.Massoglia, President
Massoglia Technical Consulting, Inc.
cmassoglia@voyager.net
In MI 517-676-9700 or in NC 919-363-9395



----- Original Message -----
From: "Jose Vega" <jvega@platt.com>
To: <RPG400-L@midrange.com>
Sent: Thursday, 21 June, 2001 12:59
Subject: Detach Journal Receiver


> Is there a specific command that is used to detach a journal receiver? I
> am trying to delete the receiver so that I can create a new one but I
> cannot while it is attached. I am looking through the manual sc418079
> for a command and cannot find it.
> Thanks in advance,
> Newbie


+---
| This is the RPG/400 Mailing List!
| To submit a new message, send your mail to RPG400-L@midrange.com.
| To subscribe to this list send email to RPG400-L-SUB@midrange.com.
| To unsubscribe from this list send email to RPG400-L-UNSUB@midrange.com.
| Questions should be directed to the list owner/operator: david@midrange.com
+---