Re: restore library of files some with journals

Hi Jim,

After you have created the new library (with create schema), you need to
stop the journaling for the target library, and start it again with
specific parameters set.
There is an IBM document that describes the requirements.

https://www.ibm.com/docs/en/i/7.5?topic=journaling-automatically-starting

In our environment I do this all the time when creating test environments.
Below is a snippet from our process.

CHGVAR VAR(&TEXT) +
VALUE('CREATE SCHEMA' *BCAT &DTALIB )
RUNSQL SQL(&TEXT)
CHGVAR VAR(&TEXT) +
VALUE('Datalib' *BCAT &IFSENV *BCAT &ENVTYP )
CHGOBJD OBJ(QSYS/&DTALIB) +
OBJTYPE(*LIB) +
TEXT(&TEXT)
CHGVAR VAR(&TEXT) +
VALUE('Journal for' *BCAT &DTALIB )
CHGOBJD OBJ(&DTALIB/QSQJRN) +
OBJTYPE(*JRN) +
TEXT(&TEXT)
/* restart journaling because of *RSTOVRJRN requirement */
/* otherwise tables will keep journaling to original journal */
ENDJRNLIB LIB(&DTALIB)
MONMSG MSGID(CPC7002)
STRJRNLIB LIB(&DTALIB) +
JRN(&DTALIB/QSQJRN) +
INHRULES((*ALL *RSTOVRJRN *INCLUDE *BOTH))
MONMSG MSGID(CPC7001)
/* restore and start journaling the objects to the journal of this lib
*/
RSTLIB SAVLIB(&DTAPRV) +
DEV(*SAVF) +
SAVF(&REFSAVLIB/&DTAPRV) +
OPTION(*NEW) +
RSTLIB(&DTALIB) +
OMITOBJ((*ALL/QSQJRN*)) +
STRJRN(*YES)
MONMSG MSGID(CPF3773 CPF3848)

Best regards,
Arco
--

Op di 31 dec. 2024 16:26 schreef Jim Franz <franz9000@xxxxxxxxx>:

For testing, created an empty TEST lib, and restored PROD library
containing files, journals, journal receivers to TEST..
The journals and receivers would not restore (and i understand why) but the
files now in lib TEST say they are journalled in DSPFD, and indicate the
journal in the PROD library. It's like the file description not updated in
the restore, but the file not really journalled.

I ran a test updating a file in TEST, and no entry made in the PROD
receiver (good..) and no errors indicated in joblog. For my test, the
journal not important,

Two questions:
Do i need to take the step of ENDJRNPF for each file in the TEST lib that
is journalled (assuming it would not affect in any way the real journal in
PROD)?

Is CPYLIB a better way to create a test lib? I see this in help text - The
journal inherit rules for the existing library are not copied to the new
library.
v7r5
Jim Franz
--