RE: DTAQ monitor.

[Scott Mildenberger <Smildenber@xxxxxxxxxxxx>]

Ken,

My previous version was the wrong program (hope I didn't confuse too much),
here is the one that reads the dataq

Scott MIldenberger

     h dftactgrp(*no)
     h actgrp(*new)
     h bnddir('MRLBIND')
     h option(*srcstmt : *noshowcpy : *nodebugio)

      *
      * Calls QRCVDTAQ for a data queue associated with a spool file.
      * The wait time is negative so it always waits for an entry.
      *
      * Parameters
      *
     d dataq           S             10A   inz('MRLMKTD3')
     d Library         S             10a   inz('*LIBL  ')
     d Length          S              5  0 inz(132)
     d Wait            S              5  0
      *
     d Spool_Num_Dec   S              5  0
      *
      * Outq Information returned to the Dataq
      *
     d Data            DS
     d Function                      10a
     d Type                           2a
     d Job_Name                      10a
     d User_Name                     10a
     d Job_Number                     6a
     d Spool_File                    10a
     d Spool_Num_Bin                  8b 0
     d Outq_Name                     10a
     d Outq_Library                  10a
     d Reserved                      56a

      /copy common/qprotosrc,sys_utils

      * Set Wait time
     c                   eval      wait = -1

     c                   do        *hival

     c                   call      'QRCVDTAQ'
     c                   parm                    dataq
     c                   parm                    Library
     c                   parm                    length
     c                   parm                    data
     c                   parm                    wait
      *
      * Use a control Spool file to terminate the program
      *
     c                   if        Spool_File = 'EXIT'
     c                   leave
     c                   end
      *
     c                   z-add     Spool_Num_Bin Spool_Num_Dec
      * Call send CLP
     c                   call(e)   'MRLMKTD3C'
     c                   parm                    spool_file
     c                   parm                    job_name
     c                   parm                    user_name
     c                   parm                    job_number
     c                   parm                    spool_num_dec

     c                   enddo

     c                   eval      *inlr = *on

>
> > -----Original Message-----
> > From: Shields, Ken [mailto:kenshields@ppg.com]
> > Sent: Tuesday, June 25, 2002 2:26 PM
> > To: 'Midrange Mailing LIst'
> > Subject: DTAQ monitor.
> >
> >
> > Hi Group..
> >     I have a need to create an output queue and using a
> > DTAQ parm, have it send an entry to the data queue as soon as
> > a report appears on the queue.
> >     Has anyone an example of a program that will monitor a
> > data queue, read the entry to obtain the Spool id#'s?
> _______________________________________________
> This is the Midrange Systems Technical Discussion
> (MIDRANGE-L) mailing list
> To post a message email: MIDRANGE-L@midrange.com
> To subscribe, unsubscribe, or change list options,
> visit: http://lists.midrange.com/cgi-bin/listinfo/midrange-l
> or email: MIDRANGE-L-request@midrange.com
> Before posting, please take a moment to review the archives
> at http://archive.midrange.com/midrange-l.
>