RE: File Transfer Support (was:ftp from 400 to 400)

>>the QY2FTML api might be what you are looking for
>
>Ooooh! Where is the documentation?
>Is it TCP/IP? I found a reference to it
>on Info Center, says it's S/36 file transfer,
>found it in Tips & Tools for Security

I couldn't find it in the Infocenter either.  It's SNA though.  Here's a
command/CL I've had since the S/38 days:

CMD 'File transfer support'

             PARM       KWD(OPTION) TYPE(*CHAR) LEN(1) RSTD(*YES) +
                          VALUES('S' 'R') MIN(1) PROMPT('Send or +
                          Receive')
             PARM       KWD(FROMLIB) TYPE(*NAME) LEN(10) MIN(1) +
                          PROMPT('From library name')
             PARM       KWD(FROMFILE) TYPE(*NAME) LEN(10) MIN(1) +
                          PROMPT('From file name')
             PARM       KWD(FROMMBR) TYPE(*NAME) LEN(10) MIN(1) +
                          PROMPT('From member name')
             PARM       KWD(TOLIB) TYPE(*NAME) LEN(10) DFT(*FROMLIB) +
                          SPCVAL((*FROMLIB)) PROMPT('To library name')
             PARM       KWD(TOFILE) TYPE(*NAME) LEN(10) +
                          DFT(*FROMFILE) SPCVAL((*FROMFILE)) +
                          PROMPT('To file name')
             PARM       KWD(TOMBR) TYPE(*NAME) LEN(10) DFT(*FROMMBR) +
                          SPCVAL((*FROMMBR)) PROMPT('To member name')
             PARM       KWD(REPLACE) TYPE(*CHAR) LEN(1) RSTD(*YES) +
                          DFT('Y') VALUES('Y' 'N') PROMPT('Replace?')
             PARM       KWD(RMTLOCNAME) TYPE(*CHAR) LEN(8) +
                          DFT('remote') PROMPT('Remote system name')
             PARM       KWD(PASSWORD) TYPE(*CHAR) LEN(10) +
                          DSPINPUT(*NO) PROMPT('Password at remote +
                          system')

           /* File Transfer Support to/from remote AS/400 */

PGM (&OPTION    +
     &FROMLIB   +
     &FROMFILE  +
     &FROMMBR   +
     &TOLIB     +
     &TOFILE    +
     &TOMBR     +
     &REPLACE   +
     &RMTLOC    +
     &PASSWORD)

DCL &OPTION    *CHAR  1
DCL &FROMLIB   *CHAR 10
DCL &FROMFILE  *CHAR 10
DCL &FROMMBR   *CHAR 10
DCL &TYPE      *CHAR  6   /* Not used on AS/400 */
DCL &TOLIB     *CHAR 10
DCL &TOFILE    *CHAR 10
DCL &TOMBR     *CHAR 10
DCL &TODATE    *CHAR  6   /* Not used on AS/400 */
DCL &REPLACE   *CHAR  1
DCL &RMTLOC    *CHAR  8
DCL &PASSWORD  *CHAR 10
DCL &RTNCODE   *CHAR  1
DCL &MESSAGEID *CHAR  8

IF (&TOLIB  *EQ '*FROMLIB')  (CHGVAR &TOLIB  &FROMLIB)
IF (&TOFILE *EQ '*FROMFILE') (CHGVAR &TOFILE &FROMFILE)
IF (&TOMBR  *EQ '*FROMMBR')  (CHGVAR &TOMBR  &FROMMBR)

CALL QSYS/QY2FTML (&OPTION    +
                   &FROMLIB   +
                   &FROMFILE  +
                   &FROMMBR   +
                   &TYPE      +
                   &TOLIB     +
                   &TOFILE    +
                   &TOMBR     +
                   &TODATE    +
                   &REPLACE   +
                   &RMTLOC    +
                   &PASSWORD  +
                   &RTNCODE   +
                   &MESSAGEID)

ENDPGM